What's wrong with my altered version of zip?

Question

I'm trying to write a function that is similar to zip but that won't discard extra elements. I feel like I've made a really dumb error somewhere.

Example input:

zipMaybe [1,2,3] [1,2]

Desired output:

[(Just 1, Just 1), (Just 2, Just 2), (Just 3, Nothing)]

---

zipMaybe :: [a] -> [b] -> [(Maybe a, Maybe b)]
zipMaybe (a:as) (b:bs) = (Just a, Just b) : zip as bs -- line with error
zipMaybe (a:as) [] = (Just a, Nothing) : zip as []
zipMaybe [] (b:bs) = (Nothing, Just b) : zip [] bs
zipMaybe _ _ = []

This, however won't compile.

Test.hs:2:49:
    Couldn't match type `a' with `Maybe a'
      `a' is a rigid type variable bound by
          the type signature for
            zipMaybe :: [a] -> [b] -> [(Maybe a, Maybe b)]
          at Test.hs:1:13
    Expected type: [Maybe a]
      Actual type: [a]
    In the first argument of `zip', namely `as'
    In the second argument of `(:)', namely `zip as bs'
    In the expression: (Just a, Just b) : zip as bs

Answer 1

You should call zipMaybe recursively instead of backing off to vanilla zip, which has the wrong type.

zipMaybe :: [a] -> [b] -> [(Maybe a, Maybe b)]
zipMaybe (a:as) (b:bs) = (Just a, Just b) : zipMaybe as bs
zipMaybe (a:as) [] = (Just a, Nothing) : zipMaybe as []
zipMaybe [] (b:bs) = (Nothing, Just b) : zipMaybe [] bs
zipMaybe _ _ = []

Btw., there's a shorter definition of this function:

zipMaybe (x:xs) (y:ys)  =  (Just x, Just y) : zipMaybe xs ys
zipMaybe xs     []      =  [(Just x, Nothing) | x <- xs]
zipMaybe []     ys      =  [(Nothing, Just y) | y <- ys]