vim copy and paste via a shared file

Question

How to augment vim yank and paste, so when I yank, vim writes the content to a file. When I paste, it uses the content from the file. I want to have a system wide file which serves as a global buffer.

Context: I run vim in different tmux splits on a remote server (over ssh). I want seamlessly copy and paste between vims in tmux splits. I tried a bunch of plugins, but none of them worked, thus the question.

Answer 1

I believe vim allows you to do it like this:

1. Yank someting in file A
2. :wv and hit enter
3. Go to file B
4. :rv and hit enter
5. Hit p to paste the content of your (now) global clipboard

This should work across your different vim sessions independently of whether they run in different tmux panes or not.

Answer 2

You want to have a look at:

• map-operator because y is an operator: a motion pending command
• readfile() and writefile() cause the r or w are commands, nice to use but not for scripts
• visualmode() to get the selection

The shared file was hardcoded /tmp/yank.txt:

function! Yank(type, ...)
  " Invoked from Visual mode, use gv command.
  if a:0
    silent exe "normal! gvy"
  elseif a:type == 'line'
    silent exe "normal! '[V']y"
  else
    silent exe "normal! `[v`]y"
  endif

  call writefile([@@], '/tmp/yank.txt')
endfunction


function! Paste(is_back)
  let @t = join(readfile('/tmp/yank.txt'), '')
  if a:is_back
    normal! "tP
  else
    normal! "tp
  endif
endfunction


nnoremap y :set opfunc=Yank<CR>g@
nmap Y Vy
vnoremap y :call Yank(visualmode(), 1)<CR>
vnoremap Y :call Yank(visualmode(), 1)<CR>


nnoremap p :call Paste(0)<CR>
nnoremap P :call Paste(1)<CR>