QML - How to send/pass variable from one qml file to other qml file

Question

How to send a variable, or signal between qml files ?

http://i.stack.imgur.com/MChCG.png

1. Mainwindow -> create a component Item2.qml
2. MainWindow -> create a component item1.qml
3. item1.qml -> create a component Item3.qml
4. Item3.qml -> change/send variable or signal to ItemII.qml(is created in mainwindow) - How ?

Someone could write a small example ?

Answer 1

Example code:

Item1.qml

//Item 1
import QtQuick 2.1

Rectangle {
    width: 200
    height: 100
    color:"red"
    Text{
        anchors.centerIn: parent
        font.pixelSize: 16
        text:"Item1"
        width:parent.width
        horizontalAlignment: Text.AlignRight
        color:"white"
    }
}

Item2.qml

//Item 2
import QtQuick 2.1

Rectangle {
    width: 100
    height: 100
    color:"blue"        
    Text{
        anchors.centerIn: parent
        font.pixelSize: 16
        text:"Item2"
        color:"white"
    }
}

Item3.qml

//Item 3
import QtQuick 2.1

Rectangle {
    id:item3
    width: item3Area.pressed?90:100
    height: item3Area.pressed?90:100
    color:"green"
    signal superAwesomeSignal(string txt)
    Text{
        anchors.centerIn: parent
        font.pixelSize: 16
        text:"Item3"
        color:"white"
    }
    MouseArea{
        id:item3Area
        anchors.fill: parent
        onClicked:item3.superAwesomeSignal("Hello, from Item 3 ")
    }
}

Main.qml

//Main.qml
import QtQuick 2.0

Rectangle {
    width: 360
    height: 360
    Item1{
        anchors.top: parent.top
        anchors.left: parent.left
        Item3{
            id:item3
            anchors.top: parent.top
            onSuperAwesomeSignal: item2.item3SignalReceived(txt)
        }
    }
    Item2{
        id:item2
        anchors.bottom: parent.bottom
        signal item3SignalReceived(string txt)
        onItem3SignalReceived:console.debug(txt)
    }
}