Passing arguments to a perl package while using it

Question

How to pass some arguments while using a package, for example:

use Test::More tests => 21;   

I wasn't able to find any valuable documentation about this featue. Are there any pros and cons of passing such arguments?

Answer 1

use My::Module LIST does two things: 1) It requires My::Module; and 2) Invokes My::Module->import(LIST).

Therefore, you can write your module's import routine to treat the list of arguments passed any which way you want. This becomes even easier if you are indeed writing an object oriented module that does not export anything to the caller's namespace.

Here's a rather pointless example:

package Ex;

use strict;
use warnings;

{
    my $hello = 'Hello';
    sub import {
        my $self = shift;
        my $lang = shift || 'English';
        if ($lang eq 'Turkish') {
            $hello = 'Merhaba';
        }
        else {
            $hello = 'Hello';
        }
        return;
    }

    sub say_hello {
        my $self = shift;
        my $name = shift;

        print "$hello $name!\n";
        return;
    }
}

__PACKAGE__;
__END__

And a script to use it:

#!/usr/bin/env perl

use strict;
use warnings;

use Ex 'Turkish';
Ex->say_hello('Perl');

Ex->import;
Ex->say_hello('Perl');

Output:

$ ./imp.pl
Merhaba Perl!
Hello Perl!