Make emacs next-buffer skip *Messages* buffer

Question

I'd like to make a simple change to Emacs so that the next-buffer and previous-buffer commands (which I have bound to C-x <RIGHT> and C-x <LEFT> will skip over the *Messages* buffer.

I'm using Emacs 24 and the Emacs Starter Kit.

I've read the following related questions and answers, but they are not what I want:

• Buffer cycling in Emacs: avoiding scratch and Messages buffer
• Emacs disable *Messages* buffer
• Emacs Lisp Buffer out of focus function?

Here are some of the reasons why they don't work:

• I'd like to keep it as simple as possible. Fewer configuration changes are better.
• I don't want to kill or prevent *Messages* altogether.
• (add-to-list 'ido-ignore-buffers "^\*Messages\*" helps with my C-x b (ido-switch-buffer) but does not change how next-buffer and previous-buffer behave.

Answer 1

This way you can avoid the infinite loop:

(defun next-code-buffer ()
  (interactive)
  (let (( bread-crumb (buffer-name) ))
    (next-buffer)
    (while
        (and
         (string-match-p "^\*" (buffer-name))
         (not ( equal bread-crumb (buffer-name) )) )
      (next-buffer))))
(global-set-key [remap next-buffer] 'next-code-buffer)

This code loops over non-starred buffers ("^\*"). For your case (only avoid *Messages*) it would be:

(defun next-code-buffer ()
  (interactive)
  (let (( bread-crumb (buffer-name) ))
    (next-buffer)
    (while
        (and
         (equal "*Messages*" (buffer-name))
         (not ( equal bread-crumb (buffer-name) )) )
      (next-buffer))))
(global-set-key [remap next-buffer] 'next-code-buffer)

You can write previous-code-buffer just replacing every next-buffer with previous-buffer.

Answer 2

This is what I'm using, based on Diego's answer:

(setq skippable-buffers '("*Messages*" "*scratch*" "*Help*"))

(defun my-next-buffer ()
  "next-buffer that skips certain buffers"
  (interactive)
  (next-buffer)
  (while (member (buffer-name) skippable-buffers)
    (next-buffer)))

(defun my-previous-buffer ()
  "previous-buffer that skips certain buffers"
  (interactive)
  (previous-buffer)
  (while (member (buffer-name) skippable-buffers)
    (previous-buffer)))

(global-set-key [remap next-buffer] 'my-next-buffer)
(global-set-key [remap previous-buffer] 'my-previous-buffer)

It is not great yet, because it will hang if there are no buffers other than the skippable-buffers I list. I use C-g to break out of the loop when it happens as a hackaround.