In Haskell, why do i have to use the dollar sign in this code?

Question

I'm still trying to crack this code:

import Data.Char
groupsOf _ [] = []
groupsOf n xs = 
    take n xs : groupsOf n ( tail xs )

problem_8 x = maximum . map product . groupsOf 5 $ x
main = do t <- readFile "p8.log" 
      let digits = map digitToInt $concat $ lines t
      print $ problem_8 digits

In problem_8 x = maximum . map product . groupsOf 5 $ x why can't it just be groupsOf 5 x ? is it because x will later be expanded to some other expressions(here it will be: digits = map digitToInt $concat $ lines t ) ? is this the so-called lazy(x wont be expanded now, but maybe later) ?

Answer 1

Without the $, the precedence works out like this:

maximum . map product . (groupsOf 5 x)

Since . (function composition) takes two functions as arguments, and groupsOf 5 x cannot return a function, this is an error.

With the $, the precedence works out like this:

(maximum . map product . groupsOf 5) x

This is equivalent (via function composition) to:

maximum (map product (groupsOf 5 x))

or:

maximum $ map product $ groupsOf 5 x

(however stringing along $ like this is considered poor style)

This has nothing to do with laziness, note.

Answer 2

You don't have to use $, in fact, you never have to use it.

In your case, the pointless^H^H^H^Hsfree notation suggests itself: Instead of

problem_8 x = maximum . map product . groupsOf 5 $ x

which is equivalent to:

problem_8 x = (maximum . map product . groupsOf 5) x

we can leave out the x on both sides of the equation:

problem_8 = maximum . map product . groupsOf 5

Answer 3

As a bdonlan said, $ is a function application and . is functional composition.

Use hoogle to figuring out what some keyword are doing. It also could be helpful to showing function signature and module name where it's from.