How do you resize images in Groovy?

Question

How do you resize/reduce the size of JPG images in Groovy?

Answer 1

Or, if you don't want to load an external dependency, just do it normally:

import static java.awt.RenderingHints.*
import java.awt.image.BufferedImage
import javax.imageio.ImageIO

def img = ImageIO.read( new File( '/tmp/image.png' ) )

def scale = 0.5

int newWidth = img.width * scale
int newHeight = img.height * scale

new BufferedImage( newWidth, newHeight, img.type ).with { i ->
  createGraphics().with {
    setRenderingHint( KEY_INTERPOLATION, VALUE_INTERPOLATION_BICUBIC )
    drawImage( img, 0, 0, newWidth, newHeight, null )
    dispose()
  }
  ImageIO.write( i, 'png', new File( '/tmp/scaled.png' ) )
}

Answer 2

The imgscalr library has a simple API to enable this.

• Download the imgscalr-lib jar (currently version 4.2)
• You can then resize an image in one call, eg Scalr.resize(imageIn, 1800)
• By default the aspect ratio is kept the same, the 2nd argument is the maximum widght (or height) of the new Image

Here's a full working example...

import org.imgscalr.Scalr
import java.awt.image.BufferedImage
import javax.imageio.ImageIO

def imageFile = new File("C:\\resize-image\\fullsize.jpg")
def imageIn = ImageIO.read(imageFile);
def newFile = new File("C:\\resize-image\\resized.jpg")

BufferedImage scaledImage = Scalr.resize(imageIn, 1800);
ImageIO.write(scaledImage, "jpg", newFile);

println "Before: Width:"+imageIn.getWidth()+" Height:"+imageIn.getHeight()+" Size: "+ imageFile.size()
println "After: Width:"+scaledImage.getWidth()+" Height:"+scaledImage.getHeight() +" Size: "+ newFile.size()

Either add the imgscalr lib to your class path or call groovy with -cp...

groovy -cp imgscalr-lib-4.2.jar resize-image.groovy