Does Backwards admit a Monad instance?

Question

I just asked this on haskell-cafe, but I figure I might as well ask here too. Is the following Monad instance for Backwards m valid?

{-# Language RecursiveDo #-}

import Control.Applicative.Backwards
import Control.Monad.Fix

instance MonadFix m => Monad (Backwards m) where
  m >>= f = Backwards $
    do
      fin <- forwards (f int)
      int <- forwards m
      pure fin

If so, could I also add this?

instance MonadFix m => MonadFix (Backwards m) where
  mfix f = Backwards $ mfix (forwards . f)

Answer 1

No, it is not valid; the monad laws at best hold in some approximate fashion. As Petr Pudlák's answer shows, Backwards m >>= f does not behave very nicely when f is strict in its argument.

According to the monad laws,

pure () >>= (\() -> m)   =   m

But with this instance, if I'm not mistaken,

pure () >>= (\() -> m) = Backwards $ do
  fin <- forwards (int `seq` m)
  int <- pure ()
  pure fin
  = Backwards $ fmap fst $ mfix $ \ ~(_, int) -> do
     fin <- forwards (int `seq` m)
     pure (fin, ())

If the underlying monad is "strict" (i.e., its >>= is strict in its left operand), this will diverge.