yes/no batch file

Question

In my batch file I want to ask the user a question.

I wrote the following:

SET /P ANSWER=Click Y to continue or N to stop (Y/N)

but I get the message without the last ).

Someone know why?

Thanks!

Answer 1

Because you're using that prompt within a parenthesised block, e.g.

if ... (
  ...
  set /P ANSWER=Blah (Y/N)
)

or

for %%x in (...) do (
  ...
  set /P ANSWER=Blah (Y/N)
)

You have to escape the closing parenthesis in that case:

SET /P ANSWER=Click Y to continue or N to stop (Y/N^)

or quote the whole argument:

SET /P "ANSWER=Click Y to continue or N to stop (Y/N)"

otherwise it closes the block. And if you had anything after that closing parenthesis you'd get a syntax error.

An easier method of what you do there would probably be the choice command:

choice /M "Press Y to continue or N to stop" /c YN

You can then check the errorlevel afterwards to find out the user's choice:

if errorlevel 255 (
  echo Error
) else if errorlevel 2 (
  echo No.
) else if errorlevel 1 (
  echo Yes.
) else if errorlevel 0 (
  echo Ctrl+C pressed.
)