How to get each item of a comma separated string assigned to an environment variable processed within a loop?

Question

The FOR loop only outputs the first item of the list and I'm trying to go over the whole list.

@ECHO OFF
set list=this,is,a,list
FOR /f "tokens=1* delims=," %%a IN ("%list%") DO echo %%a
pause

Answer 1

The FOR /F command split a line in several tokens, that must be referenced individually via separate letters:

@ECHO OFF
set list=this,is,a,list
FOR /f "tokens=1-4 delims=," %%a IN ("%list%") DO (
   echo %%a
   echo %%b
   echo %%c
   echo %%d
)
pause

The plain FOR command process a series of elements separated by space, or by the standard Batch file delimiters: comma, semicolon or equal-sign:

@ECHO OFF
set list=this,is,a,list
FOR %%a IN (%list%) DO echo %%a
pause

Answer 2

Open a command prompt window, run for /? and read the output help.

With tokens=1* the first string delimited by 1 or more commas (,,, is like 1 comma!) is assigned to loop variable a which is here the word this. And the rest of the string being is,a,list is assigned to loop variable b (next after a in ASCII table) which is not referenced at all in provided code snippet.

Here is a batch code demonstrating how to process each substring of a comma separated string:

@echo off
set "List=this,is,a,list"
set ItemCount=0

:NextItem
if "%List%" == "" pause & goto :EOF

set /A ItemCount+=1
for /F "tokens=1* delims=," %%a in ("%List%") do (
    echo Item %ItemCount% is: %%a
    set "List=%%b"
)
goto NextItem

The output is:

Item 1 is: this
Item 2 is: is
Item 3 is: a
Item 4 is: list

There are of course also other solutions possible. This is just an example.

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• echo /?
• for /?
• goto /?
• if /?
• pause /?
• set /?