Why is `a::->func;` valid?

Question

package a;
sub func {
print 1;
}
package main;
a::->func;

IMO it's enough to have a::func,a->func.

a::->func; looks very strange to me, why Perl supports this kind of strange looking syntax?

Answer 1

To quote chromatic's excellent recent blog post on the topic at Modern Perl blog: "To avoid bareword parsing ambiguity."

To illustrate why such syntax is useful, here's an example evolved from your sample:

package a;
our $fh;
use IO::File;
sub s {
    return $fh = IO::File->new();
}

package a::s;
sub binmode {
    print "BINMODE\n";
}

package main;
a::s->binmode; # does that mean a::s()->binmode ?
               # calling sub "s()" from package a; 
               # and then executing sub "open" of the returned object?
               # In other words, equivalent to $obj = a::s(); $obj->binmode();
               # Meaning, set the binmode on a newly created IO::File object?

a::s->binmode; # OR, does that mean "a::s"->binmode() ?
               # calling sub "binmode()" from package a::s; 
               # Meaning, print "BINMODE"

a::s::->binmode; # Not ambiguous - we KNOW it's the latter option - print "BINMODE"

Answer 2

a:: is a string literal that produces the string a. All the same:

 a->func()    # Only if a doesn't exist as a function.
 "a"->func()
 'a'->func()
 a::->func()
 v97->func()
 chr(97)->func()

etc

>perl -E"say('a', a, a::, v97, chr(97))"
aaaaa