What is the use of '$' sign in String manipulation in Haskell?

Question

This code checks whether the given password is valid according to the constraints in the requirements

import Data.Char

strong :: String -> Bool
strong password = all ($ password) requirements
  where requirements = [minLength 15, any isUpper, any isLower, any isDigit] 
        minLength n str = n <= length str  

Answer 1

all ($ password) requirements
  where requirements = [minLength 15, any isUpper, any isLower, any isDigit]

By definition of all, the above is equivalent to

($ password) (minLength 15) &&
($ password) (any isUpper) &&
($ password) (any isLower) &&
($ password) (any isDigit)

Now, in Haskell a so-called section (+-*/ x) stands for (\y -> y +-*/ x), whatever is the operator +-*/ (which is $, in your case). So, we obtain

(minLength 15 $ password) &&
(any isUpper $ password) &&
(any isLower $ password) &&
(any isDigit $ password)

Finally, the operator $ is defined like this: f $ x = f x, i.e. it is the function application operator. We further simplify the code above as:

minLength 15 password &&
any isUpper password &&
any isLower password &&
any isDigit password

Answer 2

$ means "Function Application" .

> :t ($) 
($) :: (a -> b) -> a -> b

$ can be used to provide a parameter to a function. In this case you use it to apply "password" to each function the "requirements" have and have type of:

-- because $ is infix, left and right param are the 1st and 2nd respectively
-- partial apply with the right param will still need the left one (a->b)
:t ( $ "a")    
( $ "a") :: ([Char] -> b) -> b --where "b" is a bool in this case

seems familiar ?

:t (\f -> f "a")
(\f -> f "a") :: ([Char] -> b) -> b

$ password and (\f -> f password) have the same type and same behaviour: take a function and apply it over a.

When you have to apply a function over a list, you just put the function alone. But in this case you have to apply functions from a list to "password". If you omit $ it will try to do "password (any isLower)" for example, which don't make any sense.

But you can do it using a lambda like all (\f -> f password) ... to apply each function to password or you can do it with $.