Violation of Primary Key error on Identity column

Question

This is maddening! Code in question has been running for over 5 years.

Here's the scoop....

I am doing an INSERT...SELECT into a table with a primary key that is an identity column. I do not specify the key when I insert - SQL Server generates it as expected.

I am doing the insert in a stored procedure that I call in a loop (for loop in SSIS, actually). The stored procedure will insert rows in batches (configurable). It might insert 1000 rows at a time or it might insert 50,000 - doesn't matter. It will work for a random number of calls (inserting thousands of rows) and then it will fail, out of the blue, with a

Violation of primary key / duplicate

error. If I check the identity seed - it is correct. If I kick off the process again it will work fine, for a while.

The values being inserted are coming from 2 tables that I join together, as if that matters.

The bulk of my code is below:

WHILE @pk <= @max_pk
BEGIN
   INSERT INTO tbl_claim_line (fk_batch_control_group, fk_claim, fk_provider, service_from_date, service_to_date, allowed, net_paid, COB, flex_1, flex_2, flex_3, flex_4)
      SELECT
         @fk_batch_control_group
         , c.pk_claim
         , p.pk_provider
         , i.date_of_service_from
         , i.date_of_service_to
         , i.allowed_amount
         , i.net_paid_amount
         , i.cob_amount
         , i.claimline_flex_1
         , i.claimline_flex_2
         , i.claimline_flex_3
         , i.claimline_flex_4
      FROM
         tbl_import i
      INNER JOIN 
         tbl_import__claim c ON i.claim_number = c.claim_number
      LEFT JOIN 
         tbl_import__provider p ON  ISNULL(i.provider_type,'') =  ISNULL(p.provider_type,'') 
             AND ISNULL(i.provider_specialty,'') =  ISNULL(p.provider_specialty,'') 
             AND  ISNULL(i.provider_zip_code,'') =  ISNULL(p.provider_zip_code,'')
      WHERE
          pk_import = @pk

    UPDATE tbl_import 
    SET fk_claim_line = SCOPE_IDENTITY() 
    WHERE pk_import = @pk

    SET @pk += 1
END

--TABLE DEFINITIONS...
CREATE TABLE [dbo].[tbl_claim_line](
    [fk_batch_control_group] [int] NOT NULL,
    [fk_claim] [int] NOT NULL,
    [fk_provider] [int] NULL,
    [service_from_date] [date] NULL,
    [service_to_date] [date] NULL,
    [allowed] [money] NULL,
    [net_paid] [money] NULL,
    [COB] [money] NULL,
    [flex_1] [varchar](200) NULL,
    [flex_2] [varchar](200) NULL,
    [flex_3] [varchar](200) NULL,
    [flex_4] [varchar](200) NULL,
    [pk_claim_line] [int] IDENTITY(1,1) NOT NULL,
    [insert_date] [datetime] NOT NULL,
 CONSTRAINT [PK_tbl_claim_line] PRIMARY KEY NONCLUSTERED 
(
    [pk_claim_line] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY]

GO

SET ANSI_PADDING OFF
GO

ALTER TABLE [dbo].[tbl_claim_line] WITH CHECK 
ADD  CONSTRAINT [FK_tbl_claim_line_tbl_batch_control_group] 
FOREIGN KEY([fk_batch_control_group])
REFERENCES [dbo].[tbl_batch_control_group] ([pk_batch_control_group])
GO

ALTER TABLE [dbo].[tbl_claim_line] CHECK CONSTRAINT [FK_tbl_claim_line_tbl_batch_control_group]
GO

ALTER TABLE [dbo].[tbl_claim_line]  WITH CHECK 
ADD CONSTRAINT [FK_tbl_claim_line_tbl_claim] 
FOREIGN KEY([fk_claim])
REFERENCES [dbo].[tbl_claim] ([pk_claim])
ON DELETE CASCADE
GO

ALTER TABLE [dbo].[tbl_claim_line] CHECK CONSTRAINT [FK_tbl_claim_line_tbl_claim]
GO

ALTER TABLE [dbo].[tbl_claim_line]  WITH CHECK 
ADD CONSTRAINT [FK_tbl_claim_line_tbl_provider] 
FOREIGN KEY([fk_provider])
REFERENCES [dbo].[tbl_provider] ([pk_provider])
GO

ALTER TABLE [dbo].[tbl_claim_line] CHECK CONSTRAINT [FK_tbl_claim_line_tbl_provider]
GO

ALTER TABLE [dbo].[tbl_claim_line] ADD  CONSTRAINT [DF_tbl_claim_line__insert_date]  DEFAULT (getdate()) FOR [insert_date]
GO

----second table
CREATE TABLE [dbo].[tbl_import](
    [fk_claim_line] [int] NULL,
    [member_id] [varchar](50) NULL,
    [member_card_id] [varchar](50) NULL,
    [member_first_name] [varchar](50) NULL,
    [member_last_name] [varchar](50) NULL,
    [member_dob] [varchar](50) NULL,
    [member_gender] [varchar](50) NULL,
    [member_subscriber_relationship_code] [varchar](50) NULL,
    [member_address_line_1] [varchar](100) NULL,
    [member_address_line_2] [varchar](100) NULL,
    [member_city] [varchar](50) NULL,
    [member_state] [varchar](50) NULL,
    [member_zip] [varchar](50) NULL,
    [member_phone] [varchar](50) NULL,
    [member_email] [varchar](50) NULL,
    [subscriber_id] [varchar](50) NULL,
    [group_line_of_business] [varchar](50) NULL,
    [group_product] [varchar](50) NULL,
    [group_employer] [varchar](50) NULL,
    [provider_first_name] [varchar](50) NULL,
    [provider_last_or_full_name] [varchar](200) NULL,
    [provider_type] [varchar](200) NULL,
    [provider_specialty] [varchar](400) NULL,
    [provider_zip_code] [varchar](50) NULL,
    [provider_tax_id] [varchar](50) NULL,
    [medical_code_1] [varchar](10) NULL,
    [medical_code_1_description] [varchar](500) NULL,
    [medical_code_2] [varchar](10) NULL,
    [medical_code_2_description] [varchar](500) NULL,
    [medical_code_3] [varchar](10) NULL,
    [medical_code_3_description] [varchar](500) NULL,
    [medical_code_4] [varchar](10) NULL,
    [medical_code_4_description] [varchar](500) NULL,
    [medical_code_5] [varchar](10) NULL,
    [medical_code_5_description] [varchar](500) NULL,
    [medical_code_6] [varchar](10) NULL,
    [medical_code_6_description] [varchar](500) NULL,
    [medical_code_7] [varchar](10) NULL,
    [medical_code_7_description] [varchar](500) NULL,
    [medical_code_8] [varchar](10) NULL,
    [medical_code_8_description] [varchar](500) NULL,
    [medical_code_9] [varchar](10) NULL,
    [medical_code_9_description] [varchar](500) NULL,
    [medical_code_10] [varchar](10) NULL,
    [medical_code_10_description] [varchar](500) NULL,
    [medical_code_11] [varchar](10) NULL,
    [medical_code_11_description] [varchar](500) NULL,
    [medical_code_12] [varchar](10) NULL,
    [medical_code_12_description] [varchar](500) NULL,
    [medical_code_13] [varchar](10) NULL,
    [medical_code_13_description] [varchar](500) NULL,
    [medical_code_14] [varchar](10) NULL,
    [medical_code_14_description] [varchar](500) NULL,
    [medical_code_15] [varchar](10) NULL,
    [medical_code_15_description] [varchar](500) NULL,
    [medical_code_16] [varchar](10) NULL,
    [medical_code_16_description] [varchar](500) NULL,
    [date_of_service_from] [varchar](50) NULL,
    [date_of_service_to] [varchar](50) NULL,
    [claim_number] [varchar](50) NULL,
    [claim_line_number] [varchar](50) NULL,
    [original_claim_number] [varchar](50) NULL,
    [allowed_amount] [varchar](50) NULL,
    [net_paid_amount] [varchar](50) NULL,
    [cob_amount] [varchar](50) NULL,
    [date_paid] [varchar](50) NULL,
    [member_flex_1] [varchar](200) NULL,
    [member_flex_2] [varchar](200) NULL,
    [member_flex_3] [varchar](200) NULL,
    [member_flex_4] [varchar](200) NULL,
    [claim_flex_1] [varchar](200) NULL,
    [claim_flex_2] [varchar](200) NULL,
    [claim_flex_3] [varchar](200) NULL,
    [claim_flex_4] [varchar](200) NULL,
    [claimline_flex_1] [varchar](200) NULL,
    [claimline_flex_2] [varchar](200) NULL,
    [claimline_flex_3] [varchar](200) NULL,
    [claimline_flex_4] [varchar](200) NULL,
    [pk_import] [int] IDENTITY(1,1) NOT NULL,
 CONSTRAINT [PK_tbl_import] PRIMARY KEY NONCLUSTERED 
(
    [pk_import] ASC
)WITH (PAD_INDEX  = OFF, STATISTICS_NORECOMPUTE  = OFF, IGNORE_DUP_KEY = OFF, ALLOW_ROW_LOCKS  = ON, ALLOW_PAGE_LOCKS  = ON) ON [PRIMARY]
) ON [PRIMARY]

Answer 1

I ran into this and much like user3170349, it was a seed issue on the column. I'm adding some additional info, however.

First, you can run this to figure out if you have a seed problem:

DBCC CHECKIDENT ('TABLE_NAME_GOES_HERE', NORESEED);

This will give you information which will read something like this:

Checking identity information: current identity value 'XXXX', current column value 'YYYY'.

If YYYY is larger than XXXX, then you have a problem and need to RESEED the table to get things going again. You can do so with the following command:

DBCC CHECKIDENT ('TABLE_NAME_GOES_HERE', RESEED, ZZZZZ);

Where ZZZZ is the reseed value. That value should be at least one higher than YYYY. YMMV, so pick a value that is appropriate for your situation.