Raytracing from scratch

Question

I made a 3D-renderer that parses .obj files (ASCII) and projects them on to a 2d plane.

At first glance the projection model seems to be fine except one thing.

I noticed that the projection model looks a bit odd:
[1]: https://i.sstatic.net/iaLOu.png

All polygons are being drawn including the ones in the back of the model, which I should definitely not be able to see. I made a quick recherche in Wikipedia to see what this is about and I think I found something called "Sichtbarkeitsproblem" (Hidden-surface determination).

---

(DE): https://de.wikipedia.org/wiki/Sichtbarkeitsproblem
(EN): https://en.wikipedia.org/wiki/Hidden-surface_determination

---

The article mentions that this is a common thing in computer graphics and that there are many different ways to perform a "Verdeckungsberechnung" (cover up calculation).

It mentions things like using a z-Buffer and Raytracing. Now I don't really know a lot about Raytracing but It seems to be quite applicable as I later want to add a light source.

I am not sure how Raytracing works but If I just send out rays in an angle that matches the slope from the camera to every pixel on screen and check which polygon hits it first I would only end up having some polygons completely missing only due to one vertex being potentially covered.

How do other Raytracers work? Do they remove the entire polygon when not getting a hit? Remove only one or more vertecies? (which I belief would cause massive distortion in shape) or do they just render all the Polygons and arrange them in a way that they are sorted by the minimum distance to the camera? (I guess this would made it very bad at performance)

Please help me implement this into my code or give me a hint, it would mean a lot to me.

My code is as followed, and the link for the projection model (see Image no. 1) I put here: https://drive.google.com/file/d/10dpjcL2d2QB15qqTSu5p6kQ534hNOzCz/view?usp=sharing
(Note that the 3d-model and code must be in same folder in order to work)

// 12.11.2022
// Siehe Rotation Matrix in Wikipedia

// View Space: The world space vertex positions relative to the view of the camera

/* Die Verdeckungsberechnung ist zum korrekten Rendern einer 3D-Szene notwendig, weil Oberflächen,
   die für den Betrachter nicht sichtbar sind, auch nicht dargestellt werden sollten
*/

// ->  https://de.wikipedia.org/wiki/Sichtbarkeitsproblem


// TODO: Raytracing/Verdeckungsberechnung
// TODO: Texture Mapping

import java.util.Arrays;

import java.awt.Robot;


import java.nio.ByteBuffer;
import java.util.regex.Matcher;
import java.util.regex.Pattern;
import java.util.ArrayList;

byte b[];

int amount = 0;
String lines[];


PVector[][] vertices;
int[] faces;



float a = 0;


PVector cam, cam_angle, cam_move, cam_speed;

float angle = 0.0;


void setup() {
  size(800,600);
  frameRate(60);
  noCursor();

  cam  = new PVector(0, 100, -500);
  cam_angle = new PVector(0, 0, 0);
  cam_move = new PVector(0, 0, 0);
  cam_speed = new PVector(50, 50, 50);
  
  lines =  loadStrings("UM2_SkullPile28mm.obj"); 
 
  println("File loaded. Now scanning contents...");
  
  println();
  
  Pattern numbers = Pattern.compile("(-?\\d+)");
  
  
  ArrayList<PVector> vertices_ = new ArrayList<PVector>();
  ArrayList<ArrayList> faces_ = new ArrayList<ArrayList>();
  
  int parsed_lines = 0; 
  
  for(String i:lines) {
    switch(i.charAt(0)) {
      
      // Find faces
      case 'f':
        ArrayList<Integer> values = new ArrayList<Integer>();
        for(Matcher m = numbers.matcher(i); m.find(); values.add(Integer.parseInt(m.group())));
        faces_.add(values);
        break;
        
      // Find Vectors  
      case 'v':
        String s[] = i.trim().split("\\s+");
        vertices_.add(new PVector(Float.parseFloat(s[1])*20, Float.parseFloat(s[2])*20, Float.parseFloat(s[3])*20));
        break;
    };
    if(++parsed_lines % (lines.length/6) == 0 || parsed_lines == lines.length) println((int)(map(parsed_lines, 0, lines.length, 0, 100)), "%");
  }
  
  println();
  println("Done. Found", vertices_.size(), "Vertices and", faces_.size(), "faces");
  
  

  int i=0;  
  
  vertices = new PVector[faces_.size()][];
  
  for(ArrayList<Integer> f_:faces_) {   
    vertices[i] = new PVector[f_.size()]; 
    int j = 0;
    
    for(int f: f_) {
      PVector v = vertices_.get(f-1);
      vertices[i][j] = Rotate3d_x(v, -90); 
      j++;
    }
    
    i++;
  }
  
}


PVector Rotate2d(PVector p, float a) {
  // a = angle

  float[][] m2 = {
    {cos(a), -sin(a)},
    {sin(a), cos(a)}
  };

  float[][] rotated = matmul(m2, new float[][] {
    { p.x },
    { p.y }
    });

  return new PVector(rotated[0][0], rotated[1][0]);
}


PVector Rotate3d(PVector p, float[][] m2) {

  float[][] rotated = matmul(m2, new float[][] {
    { p.x },
    { p.y },
    { p.z }
    });

  return new PVector(rotated[0][0], rotated[1][0], rotated[2][0]);
}



PVector Rotate3d_x(PVector p, float a) {
  return Rotate3d(p,
    new float[][] {
    {1, 0, 0},
    {0, cos(a), -sin(a)},
    {0, sin(a), cos(a)}
    });
};

PVector Rotate3d_y(PVector p, float a) {
  return Rotate3d(p,
    new float[][] {
    {cos(a), 0, sin(a)},
    {0, 1, 0},
    {-sin(a), 0, cos(a)}
    });
}

PVector Rotate3d_z(PVector p, float a) {
  return Rotate3d(p,
    new float[][] {
    {cos(a), -sin(a), 0},
    {sin(a), cos(a), 0},
    {0, 0, 1}
    });
}

PVector Rotate3d(PVector p, PVector a) {
  return Rotate3d_z( Rotate3d_y(Rotate3d_x(p, a.x), a.y), a.z );
}



// Matrixmultiplikation
float[][] matmul(float[][] m1, float[][] m2) {

  int cols_m1 = m1.length,
    rows_m1 = m1[0].length;

  int cols_m2 = m2.length,
    rows_m2 = m2[0].length;

  try {
    if (rows_m1 != cols_m2) throw new Exception("Rows of m1 must match Columns of m2!");
  }
  catch(Exception e) {
    println(e);
  }


  float[][] res = new float[cols_m2][rows_m2];


  for (int c=0; c < cols_m1; c++) {

    for (int r2=0; r2 < rows_m2; r2++) {

      float sum = 0;
      float[] buf = new float[rows_m1];

      // Multiply rows of m1 with columns of m2 and store in buf
      for (int r=0; r < rows_m1; r++) {
        buf[r] = m1[c][r]* m2[r][r2];
      }

      // Add up all entries into sum
      for (float entry : buf) {
        sum += entry;
      }

      res[c][r2] = sum;
    }
  }

  return res;
}


PVector applyPerspective(PVector p) {
    PVector d = applyViewTransform(p);
    return applyPerspectiveTransform(d);
}

PVector applyViewTransform(PVector p) {
    // c = camera position
    // co = camera orientation / camera rotation
    PVector c = cam;
    PVector co = cam_angle;
 

    // dx, dy, dz     https://en.wikipedia.org/wiki/3D_projection   :   Mathematical Formula
    float[][] dxyz = matmul(
            matmul(new float[][]{
                    {1, 0, 0},
                    {0, cos(co.x), sin(co.x)},
                    {0, -sin(co.x), cos(co.x)}
            }, new float[][]{
                    {cos(co.y), 0, -sin(co.y)},
                    {0, 1, 0},
                    {sin(co.y), 0, cos(co.y)}
            }),

            matmul(new float[][]{
                    {cos(co.z), sin(co.z), 0},
                    {-sin(co.z), cos(co.z), 0},
                    {0, 0, 1}
            }, new float[][]{
                    {p.x - c.x},
                    {p.y - c.y},
                    {p.z - c.z},
            }));

    PVector d = new PVector(dxyz[0][0], dxyz[1][0], dxyz[2][0]);
    return d;
}


PVector applyPerspectiveTransform(PVector d) {
     // e = displays surface pos relative to camera pinhole c
    PVector e = new PVector(0, 0, 300);
    return new PVector((e.z / d.z) * d.x + e.x, (e.z / d.z) * d.y + e.y);
}


void draw() {
  background(255);
  translate(width/2, height/2);
  scale(1,-1); 
  noStroke();
  fill(0, 100, 0, 50);
  
 
  
  PVector[][] points_view = new PVector[vertices.length][];
  
  for(int i=0; i < vertices.length; i++) {
    points_view[i] = new PVector[vertices[i].length];
    for(int j=0; j < vertices[i].length; j++)
    points_view[i][j] = applyViewTransform(Rotate3d_y(vertices[i][j], angle));
  }


    // The following snippet I got from:  https://stackoverflow.com/questions/74443149/3d-projection-axis-inversion-problem-java-processing?noredirect=1#comment131433616_74443149
  
    float nearPlane = 1.0;   
    
    for (int c = 0; c < points_view.length; c++) {
      beginShape();
      
        for (int r = 0; r < points_view[c].length-1; r++) {
            // Alle Punkte verbinden
            //if (i == a) continue;
            
            PVector p0 = points_view[c][r];    
            PVector p1 = points_view[c][r+1];
             
            
             if(p0.z < nearPlane && p1.z < nearPlane){ continue; };
             
           
             if(p0.z >= nearPlane && p1.z < nearPlane)
             p1 = PVector.lerp(p0, p1, (p0.z - nearPlane) / (p0.z - p1.z));
              
             if(p0.z < nearPlane && p1.z >= nearPlane)
             p0 = PVector.lerp(p1, p0, (p1.z - nearPlane) / (p1.z - p0.z));
 
            
            // project
            p0 = applyPerspectiveTransform(p0);
            p1 = applyPerspectiveTransform(p1);
            vertex(p0.x, p0.y);
            vertex(p1.x, p1.y);

        }
        endShape();
    }
    
  
    

  
}

Answer 1

Ray tracing doesn't determine whether or not a polygon is visible. It determines what point (if any) on what polygon is visible in a given direction.

As a simplification: rasterisation works by taking a set of geometry and for each one determining what pixels it affects. Ray tracing works by taking a set of pixels, and for each one determining what geometry is visible along that direction.

With rasterisation, there are many ways of making sure that polygons don't draw in the wrong order. One approach is to sort them by distance to the camera, but that doesn't work with polygons that overlap. The usual approach is to use a z-buffer: when a polygon is rasterised, calculate the distance to the camera in each pixel, and only update the buffer if the new value is nearer to the camera than the old value.

With ray tracing, each ray returns the nearest hit location along a direction, along with what it hit. Since each pixel will only be visited once, you don't need to worry about triangles drawing on top of each other.

If you just want to project a piece of 3D geometry onto a plane, rasterisation will likely be much, much faster. At a very high level, do this:

create an RGBA buffer of size X*Y
create a z buffer of size X*Y and fill it with 'inf'
for each triangle:
    project the triangle onto the projection plane
    for each pixel the triangle might affect:
        calculate distance from camera to the corresponding position on the triangle
        if the distance is lower than the current value in the z buffer:
            replace the value in the RGBA and z buffers with the new values