Multiline function calls in Coffeescript

Question

Hi everyone: Suppose I have a function "foo" that should receive two functions as parameters. If I have two lambda functions, I can call "foo" as follows:

foo (-> 1),(-> 2)

In this case, "foo" receives two functions, one that just returns 1 and another that returns 2.

However, usually lambda functions are more complicated, so putting both functions on a single line is impractical. Instead, I would like to write two multiline lambda functions. However, I can't figure out for the life of me how to accomplish this in coffeescript- Ideally, I would want to write it as follows, but it throws an error:

foo
    ->
        1
    ,
    ->
        2

The best I can come up with that works is super ugly:

foo.apply [
                ->
                        1
        ,
                ->
                        2
        ]

Can any Coffeescript guru show me how I can do this, without getting an error? Thanks!

Answer 1

I believe this is one situation where anonymous functions seem to not be the answer. They are very practical and idiomatic in a lot of situations but even they have limitations and can be less readable if used in extreme situations.

I would define the two functions in variables and then use them as parameters:

func1 = ->
    x = 2
    y = 3
    z = x+y
    return z+2*y

func2 = ->
    a = "ok"
    return a + " if you want this way"

foo func1, func2

But if you decide lambdas would be preferable, just use the parenthesis around the parameters of foo:

foo ((->
    x = 2
    y = 3
    z = x+y
    return z+2*y
  ),(->
    a = "ok"
    return a + " if you want this way"
  )
)

It is not because you are using CoffeScript that you should avoid parenthesis at any cost :)

Answer 2

This should suffice (you could indent the second lamda if you want):

f (-> 
    x = 1
    1 + 2 * x),
-> 
    y = 2
    2 * y

given the function f:

f = (a,b) -> a() + b()

the result should give 3 + 4 = 7

Answer 3

Functions are implicitly called if a variable or function follows them. That's why

foo
  ->
    2
  ,
  ->
    3

won't work; the coffeescript compiler only sees a variable followed by an unexpected indent on the next line. Explicitly calling it

foo(
  ->
    2
, ->
    3
)

will work.

You can implicitly call a function with multiple paramenters, you just need to line up the comma with the beginning of the function call

foo ->
  2
, ->
  3