How to send and handle Http Post in asp?

Question

httpRequest.Open "POST", "www.example.com/handle.asp", False
httpRequest.setRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.send data
postResponse = httpRequest.response

How do i handle the post of the above code. in handle.asp. In handle i want to take the data being sent and add to it and then send something back to the calling page?

Answer 1

@Uzi: Here's an example --

somefile.asp calling handle.asp which is the processing script:

Option Explicit

Dim data, httpRequest, postResponse

data = "var1=somevalue"
data = data & "&var2=someothervalue"
data = data & "&var3=someothervalue"

Set httpRequest = Server.CreateObject("MSXML2.ServerXMLHTTP")
httpRequest.Open "POST", "http://www.example.com/handle.asp", False
httpRequest.SetRequestHeader "Content-Type", "application/x-www-form-urlencoded"
httpRequest.Send data

postResponse = httpRequest.ResponseText

Response.Write postResponse ' or do something else with it

Example of handle.asp:

Option Explicit

Dim var1, var2, var3

var1 = Request.Form("var1")
var2 = Request.Form("var2")
var3 = Request.Form("var3")

' Silly example of a condition / test '
If var1 = "somecondition" Then
    var1 = var1 & " - extra text"
End If

' .. More processing of the other variables .. '

' Processing / validation done... '
Response.Write var1 & vbCrLf
Response.Write var2 & vbCrLf
Response.Write var3 & vbCrLf