How to pass union types through Elm ports?

Question

I've bumped into an issue while trying out Elm. I want to pass a union type through a port but I get this error:

Port `setStorage` is trying to communicate an unsupported type.

34| port setStorage : Model -> Cmd msg
    ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
The specific unsupported type is:

    Todo.Importance

The types of values that can flow through in and out of Elm include:

    Ints, Floats, Bools, Strings, Maybes, Lists, Arrays,
    Tuples, Json.Values, and concrete records.

I've modified the Todo example as follows:

type alias Task =
    { description : String
    , completed : Bool
    , editing : Bool
    , id : Int
    , importance : Importance -- <- this is the new field
    }

type Importance
  = Normal
  | High
  | Low

This issue appears to be quite old. One commenter suggests to "pass Json.Values through ports and Json.Decode/Encode them" but how exactly to do that? The documentation appears a bit unclear and lacks full examples. Any help appreciated.

Answer 1

I've made it work with Json.Decoder/Encoder. Wasn't that difficult after all although having to serialize every single field just to pass that one union type is quite a burden.

Decoders:

modelDecoder : Json.Decoder Model
modelDecoder =
  Json.object4 Model
    ("tasks" := Json.list taskDecoder)
    ("field" := Json.string)
    ("uid" := Json.int)
    ("visibility" := Json.string)

taskDecoder : Json.Decoder Task
taskDecoder =
  Json.object5 Task
    ("description" := Json.string)
    ("completed" := Json.bool)
    ("editing" := Json.bool)
    ("id" := Json.int)
    ("importance" := Json.string `andThen` importanceDecoder)

importanceDecoder : String -> Json.Decoder Importance
importanceDecoder tag =
  case tag of
    "Normal" -> Json.succeed Normal
    "High" -> Json.succeed High
    "Low" -> Json.succeed Low
    _ -> Json.fail (tag ++ " is not a recognized tag for Importance")

And encoders:

modelToValue : Model -> Json.Encode.Value
modelToValue model =
  Json.Encode.object
    [
      ("tasks", Json.Encode.list (List.map taskToValue model.tasks)),
      ("field", Json.Encode.string model.field),
      ("uid", Json.Encode.int model.uid),
      ("visibility", Json.Encode.string model.visibility)
    ]

taskToValue : Task -> Json.Encode.Value
taskToValue task =
  Json.Encode.object
    [
      ("description", Json.Encode.string task.description),
      ("completed", Json.Encode.bool task.completed),
      ("editing", Json.Encode.bool task.editing),
      ("id", Json.Encode.int task.id),
      ("importance", importanceToValue task.importance)
    ]

importanceToValue : Importance -> Json.Encode.Value
importanceToValue importance =
  case importance of
    Normal -> Json.Encode.string "Normal"
    High -> Json.Encode.string "High"
    Low -> Json.Encode.string "Low"

Answer 2

You can't pass a union type above all because JS does not know about such a thing. So you might as well pass a string and do a case statement in javascript - I do it all the time.