How to pass a value from a fixture to a test with clojure.test?

Question

When using clojure.test's use-fixture, is there a way to pass a value from the fixture function to the test function?

Answer 1

A couple of good choices are dynamic binding and with-redefs. You could bind a var from the test namespace in the fixture and then use it in a test definition:

core.clj:

(ns hello.core
  (:gen-class))

 (defn foo [x]
  (inc x))

test/hello/core.clj:

(ns hello.core-test
  (:require [clojure.test :refer :all]
            [hello.core :refer :all]))

(def ^:dynamic *a* 4)

(defn setup [f]
  (binding [*a* 42]
    (with-redefs [hello.core/foo (constantly 42)]
      (f))))

(use-fixtures :once setup)

(deftest a-test
  (testing "testing the number 42"
    (is (= *a* (foo 75)))))

You can tell that it works by comparing calling the test directly, which does not use fixtures, to calling it through run-tests:

hello.core-test> (a-test)

FAIL in (a-test) (core_test.clj:17)
testing the number 42
expected: (= *a* (foo 75))
  actual: (not (= 4 76))
nil
hello.core-test> (run-tests)

Testing hello.core-test

Ran 1 tests containing 1 assertions.
0 failures, 0 errors.
{:test 1, :pass 1, :fail 0, :error 0, :type :summary}

This approach works because fixtures close over the tests they run, though they don't get to actually make the calls to the test functions directly (usually) so it makes sense to use closures to pass information to the test code.