How to get 'milliseconds' as a part of time in perl? [duplicate]

Question

I need to get the time in the format "20130808 12:12:12.123" i.e., "yyyymmdd hour:min:sec.msec".

I tried

my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time); 
$year += 1900;
$mon++;
if ($mon<10){$mon="0$mon"} 
if ($mday<10){$mday="0$mday"} 
if ($hour<10){$hour="0$hour"} 
if ($min<10){$min="0$min"} 
if ($sec<10){$sec="0$sec"}  but this doesn't provide the `msec` as a part of time.

How can i do that ?

Answer 1

Here's a complete script. As proposed before, it is using Time::HiRes::time for microsecond support, and it's also using POSIX::strftime for easier formatting. Unfortunately strftime cannot deal with microseconds, so this has to be added manually.

use Time::HiRes qw(time);
use POSIX qw(strftime);

my $t = time;
my $date = strftime "%Y%m%d %H:%M:%S", localtime $t;
$date .= sprintf ".%03d", ($t-int($t))*1000; # without rounding

print $date, "\n";

If you don't mind to use a CPAN module, then I would propose the excellent Time::Moment module:

use Time::Moment;
print Time::Moment->now->strftime("%Y%m%d %T%3f"), "\n";

And if it may be formatted as an ISO8601 date including a time zone offset and microseconds instead of milliseconds, then it's simply:

print Time::Moment->now->to_string, "\n";

Answer 2

use Time::HiRes

Looking at this briefly, it can provide milliseconds since epoch fairly easily but didn't seem to extend localtime(), so there's probably a bit of work involved in using it in a full calendar context.

Here's a working example:

use strict;
use warnings;

use Time::Format qw/%time/;
use Time::HiRes qw/gettimeofday/;

my $time = gettimeofday; # Returns ssssssssss.uuuuuu in scalar context

print qq|$time{'yyyymmdd hh:mm:ss.mmm', $time}\n|;