How to get an interface from an object created from a TClass?

Question

I need that some of my form classes implement the same function.

(I've discarded the idea of adding this function to a common anchestor form because I don't want to add a function which would be useless on most of my forms.)

So... I thought about using interfaces.

IMyInterface = interface
  procedure ShowHello();
end;

var  
  MyForm : TMyForm;
  MyInterface : IMyInterface;
begin
  MyForm := TMyForm.Create(Self);
  MyInterface := MyForm;
  //...
end;

In simple cases like this, it works without errors, but my application uses dynamic packages and I'm using "GetClass" function in order to obtain form classes. I tried as follows:

var
  MyForm : TForm;
  MyInterface : IMyInterface;
begin
  MyForm := TForm(GetClass('TMyForm').Create());
  MyInterface := MyForm;
end;

It causes "Incompatible types: 'IMyInterface' and 'TForm'" error. Is there a way to achieve my goal using interfaces or it would be better to try other ways?

Answer 1

Use the Supports function to check whether an interface is implemented or not.

Sample:

var
  MyForm : TForm;
  MyInterface : IMyInterface;
begin
  MyForm := TFormClass(GetClass('TMyForm')).Create(...);

  if Supports(MyForm, IMyInterface, MyInterface) then
  begin
    MyInterface.ShowHello;
  end;
end;

You need to declare GUIDs for your interfaces. Otherwise Supports doesn't work. So the interface declaration should look like this:

IMyInterface = interface
  ['{052E7D55-B633-4256-9084-37D797B01BB4}']
  procedure ShowHello();
end;