How do I call concat : %variable% when the variable has internal spaces?

Question

I am trying to concat variables in my class path using the following command, but it isn't working when the folder name contains spaces:

call concat : %variable%

where %variable% ={folder name containing space}

I tried putting quotes:

call concat : "%variable%"

but this adds 2 double-quotes in my classpath as follows:

""folder name containing space""

:concat
set CLASSPATH=%CLASSPATH%;"%1"

Answer 1

Put quotes around the entire SET statement:

SET "FOO=AB C"
SET "BAR=%FOO%D EF"
echo %BAR%

Outputs:

AB CD EF

Answer 2

Do not use additional double quotes for strings with spaces. The parameter %~ removes all pairs of double quotes around the string:

@echo off &setlocal
set "Variable="my var""
echo Variable:  %Variable%
call :concat %Variable%
goto :eof

:concat
echo concat %%1:    %1
set "NewVar=%~1"
echo concat NewVar: %newvar%
goto :eof
endlocal

Output is:

Variable:       "my var" 
concat %1:      "my var" 
concat NewVar:  my var

If you put additional double quotes around the string, the following will happen:

@echo off &setlocal
set "Variable="my var""
echo Variable:  %Variable%
call :concat "%Variable%"
goto :eof

:concat
echo concat %%1:    %1
set "NewVar=%~1"
echo concat NewVar: %newvar%
goto :eof
endlocal

With broken output:

Variable:       "my var"
concat %1:      ""my
concat NewVar:  "my

Answer 3

remove the double quote from input, use double quote around the entire set, when use the concatenated string, surrounding them by double quote, for example:

set root=%~1
@echo off
setlocal EnableDelayedExpansion
set i=0
for %%d in (
1.07 1.023 1.075 1.08 1.04
) do (
   set /A i=i+1
   set scale[!i!]=%%d
)
set i=0
for %%d in (
CO DE MH PL Pr
) do (
   set /A i=i+1
   set port[!i!]=%%d
)
for %%A in (0 1 2 3 4) do (
set "file1=%root%\Event\Events.txt"
set "file2=%root%\Port E\PortE_!port[%%A]!.txt"
set "file3=%root%\Poli E By Port\E_!port[%%A]!.txt"
%0\..\average101v2.exe "!file1!" "!file2!" "!file3!" !scale[%%A]!
)