How can I plot a function defined on the unit simplex in Mathematica?

Question

I am trying to plot a function in Mathematica that is defined over the unit simplex. To take a random example, suppose I want to plot sin(x1*x2*x3) over all x1, x2, x3 such that x1, x2, x3 >= 0 and x1 + x2 + x3 = 1. Is there a neat way of doing so, other than the obvious way of writing something like

Plot3D[If[x+y<=1,Sin[x y(1-x-y)]],{x,0,1},{y,0,1}]

?

What I want, ideally, is a way of plotting only over the simplex. I found the website http://octavia.zoology.washington.edu/Mathematica/ which has an old package, but it doesn't work on my up-to-date version of Mathematica.

Answer 1

If you want to get symmetric looking plots like in that package you linked, you need to figure out rotation matrix that puts the simplex into x/y plane. You can use this function below. It's kind of long because I left in the calculations to figure out simplex centering. Ironically, transformation for 4d simplex plot is much simpler. Modify e variable to get different margin

simplexPlot[func_, plotFunc_] := 
 Module[{A, B, p2r, r2p, p1, p2, p3, e, x1, x2, w, h, marg, y1, y2, 
   valid},
  A = Sqrt[2/3] {Cos[#], Sin[#], Sqrt[1/2]} & /@ 
     Table[Pi/2 + 2 Pi/3 + 2 k Pi/3, {k, 0, 2}] // Transpose;
  B = Inverse[A];

  (* map 3d probability vector into 2d vector *)
  p2r[{x_, y_, z_}] := Most[A.{x, y, z}];

  (* map 2d vector in 3d probability vector *)
  r2p[{u_, v_}] := B.{u, v, Sqrt[1/3]};

  (* Bounds to center the simplex *)
  {p1, p2, p3} = Transpose[A];

  (* extra padding to use *)
  e = 1/20;

  x1 = First[p1] - e/2;
  x2 = First[p2] + e/2;
  w = x2 - x1;
  h = p3[[2]] - p2[[2]];
  marg = (w - h + e)/2;
  y1 = p2[[2]] - marg;
  y2 = p3[[2]] + marg;

  valid = 
   Function[{x, y}, Min[r2p[{x, y}]] >= 0 && Max[r2p[{x, y}]] <= 1];
  plotFunc[func @@ r2p[{x, y}], {x, x1, x2}, {y, y1, y2}, 
   RegionFunction -> valid]
  ]

Here's how to use it

simplexPlot[Sin[#1 #2 #3] &, Plot3D]

_{(source: yaroslavvb.com)}

simplexPlot[Sin[#1 #2 #3] &, DensityPlot]

_{(source: yaroslavvb.com)}

If you want to see domain in the original coordinate system, you could rotate the plot back to the simplex

t = AffineTransform[{{{-(1/Sqrt[2]), -(1/Sqrt[6]), 1/Sqrt[3]}, {1/
      Sqrt[2], -(1/Sqrt[6]), 1/Sqrt[3]}, {0, Sqrt[2/3], 1/Sqrt[
      3]}}, {1/3, 1/3, 1/3}}];
graphics = simplexPlot[5 Sin[#1 #2 #3] &, Plot3D];
shape = Cases[graphics, _GraphicsComplex];
Graphics3D[{Opacity[.5], GeometricTransformation[shape, t]}, 
 Axes -> True]

_{(source: yaroslavvb.com)}

Here's another simplex plot, using traditional 3d axes from here and MeshFunctions->{#3&}, complete code here

_{(source: yaroslavvb.com)}

Answer 2

Try:

Plot3D[Sin[x y (1 - x - y)], {x, 0, 1}, {y, 0, 1 - x}]

But you can also use Piecewise and RegionFunction:

Plot3D[Piecewise[{{Sin[x y (1 - x - y)], 
    x >= 0 && y >= 0 && x + y <= 1}}], {x, 0, 1}, {y, 0, 1}, 
 RegionFunction -> Function[{x, y}, x + y <= 1]]