How can I call a subroutine whose name is a value in a hash, in Perl?

Question

$ cat test.pl
use strict;
use warnings;

sub route {
    print "hello, world!";
}

my %h;
$h{'a'} = 'route';

print "1\n";
$h{a};

print "2\n";
$h{a}();

print "3\n";
"$h{a}".();
$ perl test.pl
Useless use of hash element in void context at test.pl line 12.
Useless use of concatenation (.) or string in void context at test.pl line 18.
1
2
Can't use string ("route") as a subroutine ref while "strict refs" in use at test.pl line 15.
$

What is the right way to call route()?

Answer 1

You're trying to use $h{a} as a symbol reference. And that's explicitly disallowed by "use strict". If you turn off strict mode, then you can do it like this:

no strict;
&{$h{a}};

But the best approach is to store a "real" reference to the subroutine in your hash.

#!/usr/bin/perl

use strict;
use warnings;

sub route {
    print "hello, world!";
}

my %h;
$h{a} = \&route;

$h{a}->();

Answer 2

You have to dereference the string containing the routine name as a sub. The parenthesis are optional.

my $name = 'route';
&{$name};

As your routine name is a hash value, you have to extract it from the hash. Also as you are using strict (which is a good practice), you have to locally disable checks.

{
    no strict 'refs';
    &{$h{a}};
}

However, as davorg suggested in his answer, it would be better (performance-wise) to directly store a reference to the sub in your hash, instead of the routine name.