Emacs evil: general window movement remap

Question

This is the question I should have asked instead of this:

Emacs evil: space as a prefix key in motion state

I want to define a bunch of commands for moving, moving between, opening and closing windows and buffers that works in all states except insert mode, and are all of the form "SPC ". It would be nice to be able to set this once and be fine everywhere (except when there are conflicts, though overriding would be fine), but if that isn't easy, I would also like to know how to override keybindings in new states that I run across where my keybindings don't work. Hopefully knowing that would also help me edit keybindings in arbitrary states.

What I currently have is this:

(define-key evil-normal-state-map (kbd "SPC") nil) 
(define-key evil-motion-state-map (kbd "SPC") nil) 

(define-key evil-motion-state-map (kbd "SPC h") 'evil-window-left)
(define-key evil-motion-state-map (kbd "SPC j") 'evil-window-down)
(define-key evil-motion-state-map (kbd "SPC k") 'evil-window-up)
(define-key evil-motion-state-map (kbd "SPC l") 'evil-window-right)

(define-key evil-normal-state-map (kbd "SPC h") 'evil-window-left)
(define-key evil-normal-state-map (kbd "SPC j") 'evil-window-down)
(define-key evil-normal-state-map (kbd "SPC k") 'evil-window-up)
(define-key evil-normal-state-map (kbd "SPC l") 'evil-window-right)

and "SPC H" and so on for moving windows. It doesn't work in list-buffers or Dired. Evil leader only seems to work for normal mode.

Answer 1

We meet again.

Perhaps it'd be simpler to define a prefix keymap and bind to it. For example:

(define-prefix-command 'my-window-map)

(let ((map my-window-map))
  (define-key map "h" 'evil-window-left)
  (define-key map "j" 'evil-window-down)
  (define-key map "k" 'evil-window-up)
  (define-key map "l" 'evil-window-right)

  (define-key map "H" 'evil-window-move-far-left)
  (define-key map "J" 'evil-window-move-very-bottom)
  (define-key map "K" 'evil-window-move-very-top)
  (define-key map "L" 'evil-window-move-far-right)

  ;; And presumably, for opening/closing
  (define-key map "v" 'evil-window-vsplit)
  (define-key map "s" 'evil-window-split)
  (define-key map "c" 'evil-window-delete))

Then you can map the prefix keymap to SPC in various modes:

;; Do this for each state you want these bindings available
(define-key evil-motion-state-map " " 'my-window-map)
(define-key evil-visual-state-map " " 'my-window-map)
;; You don't need to unbind/rebind evil-normal-state-map --
;; there is no default mapping for " ". Also: unbound keys in normal
;; mode will fall through to motion bindings.

;; For particular modes (like dired and list-buffer window)
(define-key dired-mode-map " " 'my-window-map)
(define-key Buffer-menu-mode-map " " 'my-window-map)

Alternatively, you can have dired and list-buffer start in normal mode. This will likely interfere with their default mappings.

(evil-set-initial-state 'dired-mode 'normal)
(evil-set-initial-state 'Buffer-menu-mode 'normal)

---

If you find your mapping overridden by another mode (which shouldn't be common for that key), you can try adding my-window-map to evil-overriding-maps: (add-to-list 'evil-overriding-maps '(my-window-map)). This supposedly gives those maps precedence.

Disclaimer: I haven't tested this. I find it simpler to undefine keys in conflicting plugins.

---

On a side note, all these commands are already available in evil-window-map. It may be simpler for you to map SPC to that:

(define-key evil-motion-state-map " " 'evil-window-map)
(define-key evil-visual-state-map " " 'evil-window-map)
...