Cloning Objects in Raku

Question

What is the best way to clone objects in raku? I know the clone method exists, but It does not seem to work with nested objects.

For example, in this script:

#!/usr/bin/env perl6

class Group {
    has Int @!group = Array[Int].new;

    method add-item(Int $int) {
        @!group.push($int);
    }

    method print {
        say @!group;
    }
}

class GroupOfGroups {
    has Group @!multi-group = Array[Group].new;

    method add-group(Group $group) {
        @!multi-group.push($group);
    }

    method print {
        for ^@!multi-group.elems -> $i {
            @!multi-group[$i].print;
        }
    }
}

my $group = Group.new;
$group.add-item(1);
$group.add-item(2);
$group.add-item(3);

my $group-of-groups = GroupOfGroups.new;
$group-of-groups.add-group($group.clone);
$group.add-item(4);
$group.add-item(5);
$group.add-item(6);

$group-of-groups.add-group($group.clone);

$group-of-groups.print;

The output is:

[1 2 3 4 5 6]
[1 2 3 4 5 6]

But I was expecting it to be:

[1 2 3]
[1 2 3 4 5 6]

Answer 1

I wouldn't use anything other than clone to clone objects. clone is a proto method defined by Mu, but it's up to its subtypes to implement its behaviour in this case, as cloning the object does clone the array attributes, but not in the way you want. As such, you can write your own clone multis that behave like you expect:

# Group
multi method clone(::?CLASS:D: --> ::?CLASS:D) {
    my ::?CLASS:D $clone .= new;
    $clone.add-item: .clone for @!group;
    $clone
}

# GroupOfGroups
multi method clone(::?CLASS:D: --> ::?CLASS:D) {
    my ::?CLASS:D $clone .= new;
    $clone.add-group: .clone for @!multi-group;
    $clone
}

::?CLASS here is a symbol that, when used in classes, is an alias for the class itself, with :D restricting the type to instances only.

Answer 2

Hi @julio a careful reading of the docs led me to this ... works like a charm:

method clone { nextwith :foo(@!foo.clone), :bar(%!bar.clone), |%_  }

(this also helped me to understand the rational behind “restricted” language help for deep cloning)