Cannot understand result for multiline regex qr/( . $ .+ )/xms

Question

For string "aa\nbb\ncc" I want to match from the last letter left to the first newline ("a") to the end of the multi line string and expected that

"aa\nbb\ncc" =~ qr/( . $ .+ )/xms matches a\nbb\ncc

and that

"aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms matches a\nbb\ncc\n.

But I got no match for "aa\nbb\ncc" =~ qr/( . $ .+ )/xms and match c\n for "aa\nbb\ncc" =~ qr/( . $ .+ )/xms.

Using qr/( . $ ..+ )/xms I got the expected results (see example code).

Perl version 5.14.2.

Can anyone give an explanation for that behaviour?

perldoc perlre:

   m   Treat string as multiple lines.  That is, change "^" and "$" 
       from matching the start or end of the string to matching the start 
       or end of any line anywhere within the string.

   s   Treat string as single line. That is, change "." to match any character 
       whatsoever, even a newline, which normally it would not match.

       Used together, as "/ms", they let the "." match any character whatsoever, 
       while still allowing "^" and "$" to match, respectively, just after and 
       just before ewlines within the string.

   \z  Match only at end of string

Running the following example code :

#!/usr/bin/env perl

use strict;
use warnings;

print "Multiline string : ", '"aa\nbb\ncc"', "\n\n";
my $str = "aa\nbb\ncc";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc"
print_match($str, qr/( . $ .+ )/xms);    # NO MATCH ! Why ???
print_match($str, qr/( . $ .+ \z )/xms); # NO MATCH ! Why ???

print "\nMultiline string now with terminating newline : ", '"aa\nbb\ncc\n"', "\n\n";
$str = "aa\nbb\ncc\n";

print_match($str, qr/( . $ )/xms);       # matches "a"
print_match($str, qr/( . $ . )/xms);     # matches "a\n"
print_match($str, qr/( . $ .. )/xms);    # matches "a\nb"
print_match($str, qr/( . $ ..+ )/xms);   # matches "a\nbb\ncc\n"
print_match($str, qr/( . $ .+ )/xms);    # MATCHES "c\n" ! Why ???
print_match($str, qr/( . $ .+ \z)/xms);  # MATCHES "c\n" ! Why ???

sub print_match {
    my ($str, $regex) = @_;
    $str =~ $regex;
    if ( $1 ) {
        printf "--> %-20s matched : >%s< \n", $regex, $1;
    }
    else {
        printf "--> %-20s : no match !\n", $regex;
    }
}

the output is :

Multiline string : "aa\nbb\ncc"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc<
--> (?^msx:( . $ .+ ))   : no match !

Multiline string now with terminating newline : "aa\nbb\ncc\n"

--> (?^msx:( . $ ))      matched : >a<
--> (?^msx:( . $ . ))    matched : >a
<
--> (?^msx:( . $ .. ))   matched : >a
b<
--> (?^msx:( . $ ..+ ))  matched : >a
bb
cc
<
--> (?^msx:( . $ .+ ))   matched : >c
<

Answer 1

It's a bug. Please report it by running the perlbug command-line too.

$ perl -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
0

$ perl -E'say "aa\nbb\ncc\n" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
>c
<

$ perl -v
...
This is perl 5, version 16, subversion 0 (v5.16.0) built for x86_64-linux
...

Like you said, they should match "a\nbb\ncc" and "a\nbb\ncc\n" respectively. There are optimisations related to $. One of them appears to have failed to take /ms into account.

---

PS — You might be interested in use re 'debug';.

$ perl -Mre=debug -E'say "aa\nbb\ncc" =~ qr/( . $ .+ )/xms ? ">$1<" : 0'
Compiling REx "( . $ .+ )"
Final program:
   1: OPEN1 (3)
   3:   SANY (4)
   4:   MEOL (5)
   5:   PLUS (7)
   6:     SANY (0)
   7: CLOSE1 (9)
   9: END (0)
anchored ""$ at 2 minlen 2 
Matching REx "( . $ .+ )" against "aa%nbb%ncc"
   0 <> <aa%nbb%ncc>         |  1:OPEN1(3)
   0 <> <aa%nbb%ncc>         |  3:SANY(4)
   1 <a> <a%nbb%ncc>         |  4:MEOL(5)
                                  failed...
   3 <aa%n> <bb%ncc>         |  1:OPEN1(3)
   3 <aa%n> <bb%ncc>         |  3:SANY(4)
   4 <aa%nb> <b%ncc>         |  4:MEOL(5)
                                  failed...
   6 <aa%nbb%n> <cc>         |  1:OPEN1(3)
   6 <aa%nbb%n> <cc>         |  3:SANY(4)
   7 <aa%nbb%nc> <c>         |  4:MEOL(5)
                                  failed...
Match failed
0
Freeing REx: "( . $ .+ )"