Cannot echo in the same line in Batch script

Question

I have txt files that contain several lines and I need to create a log out of them to store in a log the following information:
File Name
Last modified
Count of lines containing the word "valid"

I've put together a .bat file but it splits the output in two lines.

type nul >  FilesReceived.txt & for %f in (*.log) do (
find /c "valid" %f & echo(%~tf)>> LogsReceived.txt
)

With type nul I clear the contents of the FilesReceived.txt file. Then I loop through the files of type log.
Then I count lines that contain the word valid with find /c and I also echo the last modified time stamp.

However the output looks like:

---------- transaction_20160505_1005A.log: 6492
10/06/2016 04:37 p.m.

I don't know what's generating those dashes. Ultimately I'd like to have one line per log file as follows:

transaction_20012B.log: 6492 10/06/2016 04:37 p.m.

Hope you guys can help me.

Thanks,

Bruce

Answer 1

find prints the dashes if it processes a file. It doesn't, when processing from STDIN (type file.ext /c |find "string" prints the count only).

There is a trick to write without linefeed: <nul set /p"=Hello"

If you can live with another order, it's quite easy to assemble it::

@echo off
for %%f in (*.bat) do (
  <nul set /p "=%%f %%~tf "
  type %%f|find /c "echo"
)

If you want to keep your order it's a little bit more complicated: you can't force find to write without linefeed, so you have to use a trick (another for):

@echo off
(for %%f in (*.txt) do (
  <nul set /p "=%%f: "
  for /f %%i in ('type %%f^|find /c "valid"') do (<nul set /p "=%%i ")
  echo %%~tf
))>LogsReceived.txt

Answer 2

You may get the output of find command via another for and put it at any place you wish:

@echo off

(for %%f in (*.log) do (
   for /F %%c in ('find /c "valid" ^< %%f') do echo %%f: %%c %%~tf
)) > LogsReceived.txt