Meaning of %%~dpa?

Question

I am given to maintain some batch files and i repeatedly see this line in the beginning of every batch file..

FOR /f "usebackq tokens=*" %%a IN ('%0') DO SET this_cmds_dir=%%~dpa
CD /d "%this_cmds_dir%"

Does anyone know what the first line does? What is %%~dpa? What is %0 ? What is usebackq?

Answer 1

%~dpa gives you the drive and the path of the file pointed to by %a (using double % since you're running within a script, of course). From the bottom of the for /? help in cmd.exe:

In addition, substitution of FOR variable references has been enhanced.
You can now use the following optional syntax:

%~I         - expands %I removing any surrounding quotes (")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
              environment variable and expands %I to the
              fully qualified name of the first one found.
              If the environment variable name is not
              defined or the file is not found by the
              search, then this modifier expands to the
              empty string

The modifiers can be combined to get compound results:

%~dpI       - expands %I to a drive letter and path only
%~nxI       - expands %I to a file name and extension only
%~fsI       - expands %I to a full path name with short names only
%~dp$PATH:I - searches the directories listed in the PATH
              environment variable for %I and expands to the
              drive letter and path of the first one found.
%~ftzaI     - expands %I to a DIR like output line

In the above examples %I and PATH can be replaced by other valid
values.  The %~ syntax is terminated by a valid FOR variable name.
Picking upper case variable names like %I makes it more readable and
avoids confusion with the modifiers, which are not case sensitive.

%0 is the name of the batch file running and usebackq and tokens= are options for the for command. tokens= can be used to assign words to specific variables and in this case, using * puts the whole lot into %%a.

usebackq changes how the quotes are treated around the %0 argument. Without it, single quotes would run a command and use the output of that command rather than the value of %0.

More details can be found by running the aforementioned for /?.

That PATH trick, by the way, is a nifty way to find executables on your path.

Answer 2

@Santhosh: %0 would be how the current batch file was called. That could be any of the following forms: abc.bat, abc (no .bat suffix), ..\..\abc.bat, d:\path\to\abc.bat, "e:\path with spaces\to\abc.bat" and probably some more.

Now, using %0 for further processing will not work in any case, since it is not there in a canonical form. You'll use

• %~0 : to remove quotes which may appear around %0 (if any);
• %~n0 : to just use the name of %0 without suffix;
• %~nx0 : to use the name+suffix of %0;
• %~pnx0 : to use path+name+suffix of %0 (without drive letter);
• %~dpnx0: to use driveletter+path+name+suffix of %0.

The same can be used for sanitizing %1 (first argument to %0), %2 etc. in case these arguments are files or directories.