Can I partially derive Show?

Question

I have written this code to pretty-print a tree:

data Node = A | B | C | Tree Node [Node]
    deriving (Show, Eq)

printTree' :: Int -> Node -> [String]
printTree' spaceCount (Tree node children) = (printTree' spaceCount node)
    ++ concat (map (\child -> printTree' (spaceCount+2) child) children)
printTree' spaceCount leaf = [(replicate spaceCount ' ') ++ (show leaf)]

printTree :: Node -> String
printTree node = unlines (printTree' 0 node)

Example output:

*Main> putStr $ printTree $ Tree A [Tree A [A,B,C], C]
A
  A
    A
    B
    C
  C

Now I would like to make this the implementation for show. This approach is close but I can't find a way to call the built-in show:

instance Show Node where
    show (Tree node children) = printTree (Tree node children)
    show _ = "node... can I call the built-in show here?"

(In this example, I could just deal with A, B, and C. But in the real code, there are many node types.)

Answer 1

The only way I can see to do this is to separate into two types.

data Tree node = Tree node [Tree node]
data Node = A | B | C deriving Show

instance Show node => Show (Tree node) where ....

Answer 2

Following MathematicalOrchid's reponse, the best way to do this is with a new type, but here's a better way to organize the types:

data Node = Leaf Leaf | Tree Node [Node] deriving Eq
data Leaf = A | B | C deriving (Eq, Show)

instance Show Node where
  show (Tree node children) = printTree (Tree node children)
  show (Leaf l) = show l