Batch Files. IF statements?

Question

i have a batch file that needs to apply the attrib +h command to a file, then output to a txt file and display contents on screen. This should also be done if file has not been provided or can not be found. I have this so far but can not get it to work:

---

:TOP
IF EXIST "%1" GOTO COMMAND
) ELSE
(
GOTO ERROR1

:COMMAND
attrib +h %1
SHIFT
GOTO TOP
GOTO END

:ERROR1
IF "%1"=="" GOTO ERROR2
) ELSE
(
GOTO ERROR3

:ERROR2
ECHO.
ECHO No file(s) provided. Please re run the batch file.
GOTO END

:ERROR3
ECHO.
ECHO The file was not found. Please re run the batch file.
GOTO END

:END

---

This is my first computer course and any help will be greatly appreciated. Thank you.

Answer 1

I am not to familiar with Batch, but it looks like your If statement is formatted wrong.

IF EXIST "%1" (
    GOTO COMMAND
) ELSE
(
    GOTO ERROR1
)

Answer 2

There are a few issues with this code. Firstly, batch files require specific syntax with their IF / ELSE statements.

Something like this

IF EXIST "%1" (
    echo "it's here!"
) ELSE (
    echo "it isn't here!"
)

works correctly, while something like this

IF EXIST "%1" 
(
    echo "it's here!"
) 

ELSE 
(
    echo "it isn't here!"
)

does not. The parenthesis delimit the block, so your IF command will execute everything in between ( and ) if it evaluates to true.

Secondly, you don't actually need any ELSE statements. Because you are using GOTO commands just before your ELSE commands, you will never reach the second GOTO command if the first IF evaluates to true.

Finally, with the code that you currently show, the :TOP tag that you have is unnecessary.

After all of that, you should be left with something that looks like this:

@ECHO off
IF EXIST "%1" (
    GOTO COMMAND
)
GOTO ERROR1

:COMMAND
    echo "You entered a file correctly, and it exists!"
    GOTO END

:ERROR1
    IF "%1"=="" (
        GOTO ERROR2
    )
    GOTO ERROR3

:ERROR2
    ECHO.
    ECHO No file(s) provided. Please re run the batch file.
    GOTO END

:ERROR3
    ECHO.
    ECHO The file was not found. Please re run the batch file.
    GOTO END

:END