Batch file: How to get variable's value using variable's name already stored in a string

Question

1) Quick example:

set a="Hello"
set d="a"

Now, how do I get the value of "a" using (the value of) variable d? For example, the variable name could have been entered by a user using a prompt, or the name of the variable could have been sent to a function.

None of these ideas work:

set e=%%d%%

set e=%%%d%%%

set e=set e=%%d%%
%e%

After an hour of brainstorming and Googling, I have come up with this, but it seems too complicated and clumsy - is there really no other/easier way?:

set a="Hello"
set b="Good day"
set c="Good night"

set /p d="Give me a variable name"

call :GetVarVal %%%d%%% "e"

REM This now gives the correct value:
echo %e%

goto :eof

:GetVarVal
  set "%~2=%~1"
goto :eof

2) Also, sort of similar, is there a better way to do this (ideally without a custom function):

set a="C:\Users\Blah\Documents\MP4Box\MP4Box.exe"

call :get_drive_and_path a

echo %b%

goto :eof

:get_drive_and_path
  set b=%~dp1
goto :eof

Thanks!

Answer 1

example without delayed expansion (preserves exclamation marks):

@echo off &setlocal
set "a=Hello!"
set "d=a"
call echo %%%d%%%

---

output:

Hello!

Answer 2

If I understood you correctly, the trick called "delayed expansion" should work:

SETLOCAL ENABLEDELAYEDEXPANSION
SET a=Hello
SET b=a
ECHO This is the value of a: !%b%!
SETLOCAL DISABLEDELAYEDEXPANSION

Check how it works here

Answer 3

Part 2

set file="C:\Users\Blah\Documents\MP4Box\MP4Box.exe"
for %%a in (%file%) do echo %%~dpa