Yocto's ROOTFS_POSTPROCESS_COMMAND not working?

Question

I'm trying to use this variable in order to remove a few unwanted init files after my root FS is generated, following the documentation at:

http://www.yoctoproject.org/docs/1.8/ref-manual/ref-manual.html#migration-1.6-variable-changes-variable-entry-behavior

I've added exactly the same snippet to my recipe (.bb) file, without any luck... what's wrong? This is the code I'm putting in my .bb file:

my_postprocess_function() {
   echo "hello" > ${IMAGE_ROOTFS}/hello.txt
}
ROOTFS_POSTPROCESS_COMMAND += "my_postprocess_function; "

The logs don't show any kind of error or warning, just my_postprocess_function is not executed.

Answer 1

I believe there is a bug that manifests itself based on which column you put the closing curly bracket in. Initially, I could not believe that this is the behaviour, but after I tested and confirmed it, here are my results:

$ bitbake --version
BitBake Build Tool Core version 1.28.0

I'm modifying core-image-minimal.bb as follows:

FAILING CASE

SUMMARY = "G5 - A small image just capable of allowing a device to boot."

IMAGE_INSTALL = "packagegroup-core-boot ${ROOTFS_PKGMANAGE_BOOTSTRAP} ${CORE_IMAGE_EXTRA_INSTALL}"

IMAGE_LINGUAS = " "

LICENSE = "MIT"

IMAGE_ROOTFS_SIZE ?= "8192"
IMAGE_ROOTFS_EXTRA_SPACE_append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"

inherit core-image

my_postprocess_function() {
  echo "hello" > ${IMAGE_ROOTFS}/hello.txt
 }

ROOTFS_POSTPROCESS_COMMAND += "my_postprocess_function; "

The above fails silently and does not generate hello.txt Notice how the } is indented by one space (indenting by any amount other than once space will also fail).

However, if you modify it as follows:

SUCCEEDING CASE

SUMMARY = "G5 - A small image just capable of allowing a device to boot."

IMAGE_INSTALL = "packagegroup-core-boot ${ROOTFS_PKGMANAGE_BOOTSTRAP} ${CORE_IMAGE_EXTRA_INSTALL}"

IMAGE_LINGUAS = " "

LICENSE = "MIT"

IMAGE_ROOTFS_SIZE ?= "8192"
IMAGE_ROOTFS_EXTRA_SPACE_append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"

inherit core-image

my_postprocess_function() {
  echo "hello" > ${IMAGE_ROOTFS}/hello.txt
}

ROOTFS_POSTPROCESS_COMMAND += "my_postprocess_function; "

then, hello.txt is generated.

The way I found this bug is by moving the 'inherit core-image' line to the end of the file as follows:

DIAGNOSIS

SUMMARY = "G5 - A small image just capable of allowing a device to boot."

IMAGE_INSTALL = "packagegroup-core-boot ${ROOTFS_PKGMANAGE_BOOTSTRAP} ${CORE_IMAGE_EXTRA_INSTALL}"

IMAGE_LINGUAS = " "

LICENSE = "MIT"

IMAGE_ROOTFS_SIZE ?= "8192"
IMAGE_ROOTFS_EXTRA_SPACE_append = "${@bb.utils.contains("DISTRO_FEATURES", "systemd", " + 4096", "" ,d)}"


my_postprocess_function() {
  echo "hello" > ${IMAGE_ROOTFS}/hello.txt
 }

ROOTFS_POSTPROCESS_COMMAND += "my_postprocess_function; "

inherit core-image

In which case, I got the error:

ERROR: ParseError at ......./recipes-core/images/core-image-minimal.bb:13: Shell function my_postprocess_function is never closed

I mentioned this last part in case anyone else is having weird behaviour and you have exhausted all debugging possibilities.

Answer 2

cyberguijarro only says that his code exists in a .bb recipe but didn't say if that recipe was an image recipe or not. Since he didn't accept any of the given answers, I'll suggest that his issue was that his code was not in an image recipe.