What is the quickest way to toggle hide/show hidden files on a Mac OS X Yosemite?

Question

I'm on Yosemite, and I want to toggle hide/show all the hidden files on a Mac.

Every-time, I want to do that I have to go to Terminal.app and run these command :

To show

defaults write com.apple.finder AppleShowAllFiles TRUE

To hide

defaults write com.apple.finder AppleShowAllFiles FALSE

I'm wondering if there is a better tweak out there that accomplish this in just a click of a button.

Answer 1

I prefer using this shortcut:

⌘ CMD+⇧ SHIFT+.

Answer 2

Update, considering all comments:

try
    set state to (do shell script "defaults read com.apple.finder AppleShowAllFiles") as boolean
on error
    set state to false
end try

do shell script "defaults write com.apple.finder AppleShowAllFiles " & (not state)

try
    tell application "Finder"
        set w to front window
        set t to (get target of w)
        if t is not startup disk then
            set the target of w to startup disk
        else
            set the target of w to home
        end if
        set the target of w to t
    end tell
end try

tell application (path to frontmost application as text)
    display notification "ShowAllFiles is now " & (not state)
end tell

Export the script as app and cmd-drag the app to the Finder window toolbar.