Understanding Perl regular expression modifers /m and /s [duplicate]

Question

I have been reading perl regular expression with modifier s m and g. I understand that //g is a global matching where it will be a greedy search.

But I am confused with the modifier s and m. Can anyone explain the difference between s and m with code example to show how it can be different? I have tried to search online and it only gives explanation as in the link http://perldoc.perl.org/perlre.html#Modifiers. In stackoverflow I have even seen people using s and m together. Isn't s is the opposite of m?

//s 
//m 
//g

I am not able to match multiple line using using m.

use warnings;
use strict;
use 5.012;

my $file; 
{ 
 local $/ = undef; 
 $file = <DATA>; 
};
my @strings = $file =~ /".*"/mg; #returns all except the last string across multiple lines
#/"String"/mg; tried with this as well and returns nothing except String
say for @strings;

__DATA__
"This is string"
"1!=2"
"This is \"string\""
"string1"."string2"
"String"
"S
t
r
i
n
g"

Answer 1

/m and /s both affect how the match operator treats multi-line strings.

With the /m modifier, ^ and $ match the beginning and end of any line within the string. Without the /m modifier, ^ and $ just match the beginning and end of the string.

Example:

$_ = "foo\nbar\n";

/foo$/,  /^bar/       do not match
/foo$/m, /^bar/m      match

With the /s modifier, the special character . matches all characters including newlines. Without the /s modifier, . matches all characters except newlines.

$_ = "cat\ndog\ngoldfish";

/cat.*fish/           does not match
/cat.*fish/s          matches

It is possible to use /sm modifiers together.

$_ = "100\n101\n102\n103\n104\n105\n";

/^102.*104$/          does not match
/^102.*104$/s         does not match
/^102.*104$/m         does not match
/^102.*104$/sm        matches