TabPage selection, move the Focus to the previous ActiveControl when a TabPage is reselected

Question

I need some help to focus a particular control when a TabPage is revisited. I followed many other blogs, but I wasn't able to solve the problem myself.

I created the TabPages inside a MDIForm:

Public Sub Tab_Open(Of T As {Form, New})(name As String, NameofTab As String, Tabnumber As String)

    Dim _formByName As New Dictionary(Of String, Form)
    Dim Frm As Form = Nothing

    If Not _formByName.TryGetValue(name, Frm) OrElse _formByName(name).IsDisposed Then
        Frm = New T()
        _formByName(name) = Frm
    End If

    Dim childTab As TabPage = New TabPage With {
        .Name = NameofTab & " : " & Tabnumber,
        .Text = NameofTab & " : " & Tabnumber,
        .Tag = Frm.Name
    }

    Form1.tabForms.TabPages.Add(childTab)

    Frm.TopLevel = False
    Frm.FormBorderStyle = FormBorderStyle.None
    Frm.Parent = Form1.tabForms.TabPages(Form1.tabForms.TabCount - 1)
    Frm.Dock = DockStyle.Fill
    Frm.Show()
   
    Form1.tabForms.SelectedTab = childTab
    Form1.tabForms.Visible = True
End Sub

Let's assume that in first TabPage the Focus was on a TextBox (with TabIndex = 4), now I may be click on the second TabPage.
After some calculations, when I select the previous TabPage, the Focus should be set to the TextBox with TabIndex = 4 again, but that's not happening.

I tried to create a Dictionary in the MDIForm as:

Public Tab_Last_Focus_info As New Dictionary(Of String, String())

and in SelectedIndexChanged I have this code:

 Private Sub tabForms_SelectedIndexChanged(sender As Object, e As EventArgs) Handles tabForms.SelectedIndexChanged

    If Tab_Last_Focus_info.ContainsKey(tabForms.SelectedTab.Name) Then
        Dim FullTypeName1 As String = String.Format("{0}", Tab_Last_Focus_info.Item(tabForms.SelectedTab.Name))
        Dim Indxval As String = String.Format("{1}", Tab_Last_Focus_info.Item(tabForms.SelectedTab.Name))

        Dim FullTypeName As String = Application.ProductName & "." & FullTypeName1
        Dim FormInstanceType As Type = Type.GetType(FullTypeName, True, True)
        Dim frm As Form = CType(Activator.CreateInstance(FormInstanceType), Form)
        Dim Focus_on As Integer = Integer.Parse(Indxval)

        frm.Controls(Focus_on).Focus()
        ' Not working too =>
        ' frm.Controls(Focus_on).Select() 

        ' Invisible or disabled control cannot be activated =>
        ' ActiveControl = frm.Controls(Focus_on) 'System.ArgumentException: 
    End If
End Sub

In the Form, which is opened via a Menu, I have this code for the Control that's focused:

Private Sub All_Got_Focus(sender As Object, e As EventArgs) Handles TB_ImageLoc.GotFocus, TB_CompWebsite.GotFocus,
    TB_CompPinCD.GotFocus, TB_CompPAN.GotFocus, TB_CompName.GotFocus, TB_CompMobile.GotFocus,
    TB_CompMD.GotFocus, TB_CompLL.GotFocus, TB_CompGSTIN.GotFocus, TB_CompFax.GotFocus, TB_CompEmail.GotFocus,
    TB_CompCD.GotFocus, TB_CompAreaCity.GotFocus, RTB_CompADD.GotFocus, PB_Logo.GotFocus, DTP_CompEst.GotFocus, DGV_CompList.GotFocus,
    CHKB_CompIsRegTrans.GotFocus, CB_CompStateID.GotFocus, CB_CompDistrictID.GotFocus, But_Upd.GotFocus, But_SelectLogo.GotFocus,
    But_Search.GotFocus, But_Reset.GotFocus, But_Refresh.GotFocus, But_GridSelect.GotFocus, But_Exit.GotFocus, But_Edit.GotFocus,
    But_Del.GotFocus, But_Add.GotFocus
   
    If Form1.Tab_Last_Focus_info.ContainsKey(Form1.tabForms.SelectedTab.Name) Then
        Form1.Tab_Last_Focus_info.Remove(Form1.tabForms.SelectedTab.Name)
    End If

    Form1.Tab_Last_Focus_info.Add(Form1.tabForms.SelectedTab.Name, New String() {Me.Name, Me.ActiveControl.TabIndex})
End Sub

Now in TabIndexChange I'm getting a correct value from the Dictionary, but I'm not able to focus on the required tab.

Kindly help and let me know what I am missing or what need to taken care for this issue or please let me know any other better idea for the same.

Answer 1

First thing, a suggestion: test this code in a clean Project, where you have a MDIParent and one Form with a TabControl with 2 o more TabPages, containing different types of Controls. Test the functionality, then apply to the Project that is meant to use it.

---

You need to keep track of the selected Control in a TabPage - the current ActiveControl - switch to other TabPages, restore the previous ActiveControl in a TabPage when it's brought to front again.

The procedure is simple, implemented as follows:

• To keep track of the current ActiveControl - the Control that has the Focus, you need to know when a Control becomes the ActiveControl. This Control of course must be child of a TabPage.
  The ContainerControl class (the class from which Form derives) has a protected virtual method, UpdateDefaultButton(), that's overridden in the Form class. It's used to determine which child Button is activated when a User presses the Enter Key.
  This method is called each time a new Control becomes the ActiveControl: overriding it, we can be informed when this happens, so we can check whether the new ActiveControl is one we're interested in, because it's child of a TabPage of our TabControl.

• When the new ActiveControl is one we need to keep track of, we can store the reference of this Control and the Index of the TabPage it belongs to in a collection, so we can then use this reference, when the selected TabBage changes, to set it again as the ActiveControl in its TabPage.

Here, to store the state, I'm using a Dictionary(Of Integer, Control), where the Key is the Index of the TabPage and the Value is the reference of its ActiveControl.

When the TabControl.Selected event is raised - after a TabPage has been selected - we can lookup the Dictionary and restore the previous ActiveControl of that TabPage if one was stored.

► Here, BeginInvoke() is used to defer the action of setting the new ActiveControl, because this also causes a call to UpdateDefaultButton() and this method is called before the TabControl.Selected event handler completes.

Public Class SomeMdiChildForm

    Private tabPagesActiveControl As New Dictionary(Of Integer, Control)()

    ' This method is called each time a Control becomes the ActiveControl
    Protected Overrides Sub UpdateDefaultButton()
        MyBase.UpdateDefaultButton()

        If TypeOf ActiveControl.Parent Is TabPage Then
            Dim tabPageIdx = CType(CType(ActiveControl.Parent, TabPage).Parent, TabControl).SelectedIndex
            If tabPagesActiveControl.Count > 0 AndAlso tabPagesActiveControl.ContainsKey(tabPageIdx) Then
                tabPagesActiveControl(tabPageIdx) = ActiveControl
            Else
                tabPagesActiveControl.Add(tabPageIdx, ActiveControl)
            End If
        End If
    End Sub

    Private Sub TabControl1_Selected(sender As Object, e As TabControlEventArgs) Handles TabControl1.Selected
        Dim ctrl As Control = Nothing
        If tabPagesActiveControl.TryGetValue(e.TabPageIndex, ctrl) Then
            BeginInvoke(New Action(Sub() Me.ActiveControl = ctrl))
        End If
    End Sub
End Class

C# Version:
(assume tabControl1 is the name of the TabControl instance)

public partial class SomeForm : Form
{
    private Dictionary<int, Control> tabPagesActiveControl = new Dictionary<int, Control>();

    // [...]

    // This method is called each time a Control becomes the ActiveControl
    protected override void UpdateDefaultButton()
    {
        base.UpdateDefaultButton();
        if (ActiveControl.Parent is TabPage tp) {
            var tabPageIdx = (tp.Parent as TabControl).SelectedIndex;
            if (tabPagesActiveControl.Count > 0 && tabPagesActiveControl.ContainsKey(tabPageIdx)) {
                tabPagesActiveControl[tabPageIdx] = ActiveControl;
            }
            else {
                tabPagesActiveControl.Add(tabPageIdx, ActiveControl);
            }
        }
    }

    private void tabControl1_Selected(object sender, TabControlEventArgs e)
    {
        if (tabPagesActiveControl.TryGetValue(e.TabPageIndex, out Control ctrl)) {
            BeginInvoke(new Action(() => ActiveControl = ctrl));
        }
    }
}