Suppress Gradle's JavaExec output

Question

I have gradle code below and I don't know how to avoid huge output generated by JavaExec task. I haven't found any option of JavaExec for it. If anyone knows better way of ignoring it, please share it.

def getStubOutput() {
    return new FileOutputStream(new File("${buildDir}/temp"))
}

configure(project(':jradius:dictionary-min')) {
    evaluationDependsOn(':jradius')
    sourceSets {
        main {
            java {
                srcDir "${projectDir}/target/dictionary-src"
            }
        }
    }
    dependencies {
        compile project(':jradius:core')
    }
    task genSources(type: JavaExec) {
        main = 'net.jradius.freeradius.RadiusDictionary'
        classpath configurations.all
        args = ["net.jradius.dictionary", "${projectDir}/../freeradius/dict-min", "${projectDir}/target/dictionary-src"]
        maxHeapSize = "800m"
        standardOutput = getStubOutput()
    }
    jar {
        archiveName = "jradius-dictionary-min-1.1.5-SNAPSHOT.jar"
    }
    genSources.dependsOn ':jradius:cloneJradius' 
    compileJava.dependsOn genSources
}

Answer 1

I simply use a dummy OutputStream that does nothing in its write method:

def dummyOutputStream = new OutputStream() {
    @Override
    public void write(int b) {}
}

exec {
    executable = name
    standardOutput = dummyOutputStream
    errorOutput = dummyOutputStream
    ignoreExitValue = true
}