Set named parameter for Oracle dbms_scheduler job stored procedure

Question

Is it possible to passed named arguments to for dbms_scheduler job with a type 'stored_procedure' ? I've tried this way:

-- 1) example dummy procdure
CREATE OR REPLACE PROCEDURE my_test_proc (
 param1 IN NVARCHAR2,
 param2 IN NUMBER,
 param3 IN NUMBER
) IS
BEGIN
-- ...
END;

-- 2)Example dummy job:
BEGIN    
    dbms_scheduler.create_job(
        job_name => 'my_test_job'
        ,job_type => 'STORED_PROCEDURE'
        ,job_action => 'my_test_proc'
        ,start_date => sysdate
        ,number_of_arguments => 3
        ,enabled => FALSE
        ,auto_drop =>FALSE
    );
END;
-- 3)Set named param value:
BEGIN  
    dbms_scheduler.set_job_argument_value(
        job_name => 'my_test_job'
        ,argument_name => 'param1' 
        ,argument_value => 'some value'
    );
END;  

I get following error: ORA

-27484: Argument names are not supported for jobs without a program. ORA-06512: at "SYS.DBMS_ISCHED", line 207 ORA-06512: at "SYS.DBMS_SCHEDULER", line 602 ORA-06512: at line 2

I successfully set parameter values with set_job_argument_value by using argument_position setting. But there can be cases when I will need to run stored procedures to whom I will need to set only certain parameters and this could not work. Is there a way to pass named argument to stored procedure runed by scheduler job?

Answer 1

as the error states, create a program first, then the job on that.

dbms_scheduler.create_program(program_name        => 'YOUR_PROGRAM',
                              program_type        => 'STORED_PROCEDURE',                                                          
                              program_action      => 'my_test_proc', 
                              number_of_arguments => 2,
                              enabled             => false,
                              comments            => 'Comments you want');

dbms_scheduler.define_program_argument(program_name      => 'YOUR_PROGRAM',
                                       argument_name     => 'param1',
                                       argument_position => 1,
                                       argument_type     => 'VARCHAR2',
                                       default_value     => '');
    ..etc, do for all 3.                                         

dbms_scheduler.enable (name => 'YOUR_PROGRAM');


dbms_scheduler.create_job(job_name        => 'my_test_job',
                          program_name    => 'YOUR_PROGRAM',
                          start_date      => systimestamp,
                          end_date        => null,
                          ...

dbms_scheduler.set_job_argument_value(job_name          => 'my_test_job',
                                      argument_position => 1,
                                      argument_value    => 'value');
  ...

Answer 2

I have a basic example for procedure

1.- CREATE MY PROCEDURE

CREATE OR REPLACE PROCEDURE MY_TEST_PROCEDURE (P_VAR1 VARCHAR2, P_VAR_NUMBER NUMBER)
AS 
    V_RESULT_MSG VARCHAR2(300);
BEGIN
    DBMS_OUTPUT.PUT_LINE(TO_CHAR(SYSDATE,'DD/MM/YYYY HH24:MI'));
    V_RESULT_MSG := P_VAR1;
    V_RESULT_MSG := V_RESULT_MSG||' '||P_VAR_NUMBER;

    DBMS_OUTPUT.PUT_LINE(TO_CHAR(SYSDATE,'DD/MM/YYYY HH24:MI'));
    DBMS_OUTPUT.PUT_LINE(V_RESULT_MSG);
END MY_TEST_PROCEDURE;

2.- CREATE PROGRAM

BEGIN
    DBMS_SCHEDULER.CREATE_PROGRAM(
        PROGRAM_NAME => 'MY_TEST_PROGRAM'
        ,PROGRAM_TYPE => 'STORED_PROCEDURE'
        ,PROGRAM_ACTION => 'MY_TEST_PROCEDURE'
        ,NUMBER_OF_ARGUMENTS => 2
        ,ENABLED =>  FALSE
        ,COMMENTS => 'my test program'
    );

    DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(
        PROGRAM_NAME => 'MY_TEST_PROGRAM',
        argument_name     => 'P_VAR1',
        argument_position => 1,
        argument_type     => 'VARCHAR2',
        default_value     => ''
    );

    DBMS_SCHEDULER.DEFINE_PROGRAM_ARGUMENT(
        PROGRAM_NAME => 'MY_TEST_PROGRAM',
        argument_name     => 'P_VAR_NUMBER',
        argument_position => 2,
        argument_type     => 'NUMBER',
        default_value     => ''
    );

    dbms_scheduler.enable (name => 'MY_TEST_PROGRAM');

END;

3.- CREATE JOB

BEGIN
    DBMS_SCHEDULER.CREATE_JOB (
        job_name => '"XXFLM"."MY_TEST_JOB"',
        PROGRAM_NAME => 'MY_TEST_PROGRAM'
    );

END;

4.- PL/SQL CODE TEST

DECLARE
    V_VAR1 VARCHAR2(50) := 'HOLA';
    V_VAR2 NUMBER  := 2010;

BEGIN

    dbms_scheduler.set_job_argument_value(
        job_name          => 'MY_TEST_JOB',
        argument_position => 1,
        argument_value    => V_VAR1);

    dbms_scheduler.set_job_argument_value(
        job_name          => 'MY_TEST_JOB',
        argument_position => 2,
        argument_value    => V_VAR2);

    DBMS_SCHEDULER.RUN_JOB(
        JOB_NAME            => '"XXFLM"."MY_TEST_JOB"',
        USE_CURRENT_SESSION => FALSE);

END;

5.- RESULT

SELECT * FROM ALL_SCHEDULER_JOB_RUN_DETAILS ORDER BY 1 DESC;