sed gives me ": unexpected EOF (pending }'s) error and I have no idea why

Question

I'm trying to port a GNU sed command to BSD sed (in OSX). The command is:

cat -- "$1" | sed -n -e "\${/^#/H;x;/${tapPrintTapOutputSedPattern}/p;}" \
-e "/${tapPrintTapOutputSedPattern}/{x;/${tapPrintTapOutputSedPattern}/p;b;}" \
-e "/^#/{H;b;}" \
-e "x;/${tapPrintTapOutputSedPattern}/p" \
-e "/^Bail out!/q"

It works on GNU sed, but BSD sed gives this error:

sed: 2: "/^Bail out!/q
": unexpected EOF (pending }'s)

This is the command after the variable expansions, in case it's relevant:

cat -- "test021.tap" | sed -n \
-e "\${/^#/H;x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p;}" \
-e "/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/{x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p;b;}" \
-e "/^#/{H;b;}" \
-e "x;/^not ok\|^ok \([0-9]\+ \)\?# [tT][oO][dD][oO]\|^Bail out!/p" \
-e "/^Bail out!/q"

Any ideas about why/how to fix it?

Cheers!

Answer 1

Try using newlines instead of a semicolons, at least before the branch commands (b) in the statements. See if this works:

sed -n "
  \${
    /^#/H
    x
    /${tapPrintTapOutputSedPattern}/p
  }
  /${tapPrintTapOutputSedPattern}/{
    x
    /${tapPrintTapOutputSedPattern}/p
    b
  }
  /^#/{
    H
    b
  }
  x
  /${tapPrintTapOutputSedPattern}/p
  /^Bail out!/q
" "$1"