Parse a text-string to F#-code

Question

How do I take text-string, that is supposed to be F#-code, and parse it into F#-code, to print out the results on the screen?

I'm guessing it would be solved through a feature in .NET, so it can be done through F# itself or C#.

In what way is this probably solved on tryfsharp.org?

Answer 1

The desired can be achieved using F# CodeDom provider. A minimal runnable snippet below demonstrates the required steps. It takes an arbitrary presumably correct F# code from a string and tries to compile it into an assembly file. If successful, then it loads this just synthesized assembly from the dll file and invokes a known function from there, otherwise it shows what's the problem with compiling the code.

open System 
open System.CodeDom.Compiler 
open Microsoft.FSharp.Compiler.CodeDom 

// Our (very simple) code string consisting of just one function: unit -> string 
let codeString =
    "module Synthetic.Code\n    let syntheticFunction() = \"I've been compiled on the fly!\""

// Assembly path to keep compiled code
let synthAssemblyPath = "synthetic.dll"

let CompileFSharpCode(codeString, synthAssemblyPath) =
        use provider = new FSharpCodeProvider() 
        let options = CompilerParameters([||], synthAssemblyPath) 
        let result = provider.CompileAssemblyFromSource( options, [|codeString|] ) 
        // If we missed anything, let compiler show us what's the problem
        if result.Errors.Count <> 0 then  
            for i = 0 to result.Errors.Count - 1 do
                printfn "%A" (result.Errors.Item(i).ErrorText)
        result.Errors.Count = 0

if CompileFSharpCode(codeString, synthAssemblyPath) then
    let synthAssembly = Reflection.Assembly.LoadFrom(synthAssemblyPath) 
    let synthMethod  = synthAssembly.GetType("Synthetic.Code").GetMethod("syntheticFunction") 
    printfn "Success: %A" (synthMethod.Invoke(null, null))
else
    failwith "Compilation failed"

Being fired-up it produces the expected output

Success: "I've been compiled on the fly!"

If you gonna play with the snippet it requires referencing FSharp.Compiler.dll and FSharp.Compiler.CodeDom.dll. Enjoy!

Answer 2

I'm guessing it would be solved through a feature in .NET, so it can be done through F# itself or C#.

Nope. F# provides comparatively tame metaprogramming facilities. You'll need to rip the relevant code out of the F# compiler itself.