NetLogo get the breed of a turtle

Question

i am trying to randomly pick 2 turtles of the same breed - but i´m struggling with how to do it. I have 10 different breeds. My code should first randomly pick a turtle of any breed and then pick randomly one of the same breed than the first one. But i really don´t know how to do it. Can anybody tell me how to do this? From other programming languages i´d expect, that i can store a turtle object in a variable (which works)

let source one-of turtles

and then somehow get the breed as an attribute of my source turtle like this (whick doesn´t work)

let source-breed source.getBreed

Can anybody help me please?

Answer 1

As you can see in NetLogo's documentation, each turtle has a breed variable that references the agent set containing all turtles of that breed. You can use of to access a turtle variable, or refer to it in the context of an ask block.

Here is an example:

breed [ mice mouse ]
breed [ cats cat ]
breed [ dogs dog ]

to go
  clear-all
  create-mice 10
  create-cats 10
  create-dogs 10
  let source one-of turtles
  show word "We picked: " source
  show word "The source breed is: " [ breed ] of source
  ask source [
    let other-turtle one-of other breed
    show word "Here is another turtle of the same breed: " other-turtle
  ]
end

Note the use of other in the expression one-of other breed, which means "one other turtle of my breed" (not "a turtle of another breed".)