Namespace confusion and macros

Question

I want to write a macro that uses functions from the clj-time library. In one namespace I would like to call the macro like this:

(ns budget.account
  (:require [budget.time]))

(budget.time/next-date interval frequency)

The next-date macro would be defined in another file like this:

(ns budget.time
  (:require [clj-time.core :as date]))

(defmacro next-date [interval freq]
  `(~interval ~freq))

If the macro were called with the following arguments (budget.time/next-date interval freq) and interval and freq where "weeks" and "2" repectively then the macro expand would look something like this (clj-time.core/weeks 2)

Whenever I try this from the REPL it cannot resolve the namespace.

Is there a way to force the macro to resolve interval to the arguments to the clj-time namespace? What is the best way to do this?

Thanks!

Answer 1

Macros return a list which is then evaluated in the namespace it is called from, not the namespace it is defined in. this is different than functions which evaluate in the namespace in which they where defined. This is because macros return the code to be run, instead of just running it.

if i go to another namespace, for instance hello.core and expand a call to next-date i get:

hello.core> (macroexpand-1 '(next-date weeks 2))
(weeks 2) 

then after the expansion, weeks is resolved from hello.core, in which it is of course not defined. to fix this we need the returned symbol to carry the name-space information with it.

fortunately you can explicitly resolve a symbol in a namespace with ns-resolve. It takes a namespace and a symbol and tries to find it in the namespace returning nil if it's not found

(ns-resolve 'clj-time.core (symbol "weeks"))
#'clj-time.core/weeks

next your macro will be taking a symbol and a number so we can dispense with the explicit call to symbol

(ns-resolve 'clj-time.core 'weeks)
#'clj-time.core/weeks

so now you just need a function that resolves the function and then creates a list of the resolved function followed by the number,

(defmacro next-date [interval freq]
  (list (ns-resolve 'clj-time.core interval) freq))

In the above macro all it does is make a function call which is immediatly called, so you don't even need a macro for this:

(defn next-date [interval freq]
  ((ns-resolve 'clj-time.core interval) freq))
(next-date 'weeks 2)
#<Weeks P2W>

the non-macro version requires you to quote the interval because it need it not to be evaluated before you can look it up. What the macro really buys you here is not having to include the quote, at the cost of requiring all the callers to require clj-time

of course you could also just require clj-time everywhere, but that's not really the point.