Lexical scope of my

Question

Pretty much every perl program written uses this idiom:

{
open(my $fh, '>>', $filename) || die "you lose";
print $fh $blah;
}

However, I don't want to die, I want to just skip the print. So I write:

{
print "you lose\n" unless (open(my $fh, '>>', $filename) and print $fh $blah);
}

and get "Can't use an undefined value as a symbol reference at ./o.pl line 5" for my trouble.

Removing the my (bad form) eliminates this error, as does:

{
my $fh;
print "you lose\n" unless (open($fh, '>>', $filename) and print $fh $blah);
}

but why?

Why, in the broken code, doesn't $fh exist from open(my $fh... to the close of the block (the })?

Answer 1

The my doesn't take effect until the end of the statement.

For that same reason, my $x = $x won't see the new $x on the right hand side of the statement. It'll see the old $x.

For example

use strict;
use warnings;

my $x = 42;

{
    my $x = $x + 1;
    print "inside, x = $x\n";
}

print "outside, x = $x\n";

This prints:

inside, x = 43
outside, x = 42

Your open statement is roughly equivalent to the inner my statement above. If you had $fh declared in the outer scope, surprising fun would happen: You'd probably end up printing to the wrong file.

Answer 2

You may prefer

{
  open(my $fh, '>>', $filename) || warn "you lose";
  print $fh $blah if $fh->opened;
}

Of course you can also remove the warn if you wish.

If your Perl 5 is older than version 14 then you will need to add

use IO::File

to the header of your code.

Answer 3

If you add strict and warnings to your program, you would get much more useful error messages:

use strict;
use warnings;

{
   my $filename = "test.txt";
   print "you lose\n" unless (open(my $fh, '>>', $filename) 
         and print {$fh} $blah);
}

__END__
Global symbol "$fh" requires explicit package name at test.pl line 6.
Global symbol "$blah" requires explicit package name at test.pl line 6.
Execution of test.pl aborted due to compilation errors.

The problem being that you can't declare and use a lexical variable in the same statement. $fh will only be available after the line with the open on it.