Is there an analogue of Ruby gsub method in Perl? [duplicate]

Question

Possible Duplicate:
How do I perform a Perl substitution on a string while keeping the original?

How do I do one line replacements in Perl without modifying the string itself? I also want it to be usable inside expressions, much like I can do p s.gsub(/from/, 'to') in Ruby.

All I can think of is

do {my $r = $s; $r =~ s/from/to/; $r}

but sure there is a better way?

Answer 1

Starting on the day you feel comfortable writing use 5.14.0 at the top of all of your programs, you can use the s/foo/bar/r variant of the s/// operator, which returns the changed string instead of modifying the original in place (added in perl 5.13.2).

Answer 2

The solution you found with do is not bad, but you can shorten it a little:

do {(my $r = $s) =~ s/from/to/; $r}

It still reveals the mechanics though. You can hide the implementation, and also apply substitutions to lists by writing a subroutine. In most implementations, this function is called apply which you could import from List::Gen or List::MoreUtils or a number of other modules. Or since it is so short, just write it yourself:

sub apply (&@) {                  # takes code block `&` and list `@`
    my ($sub, @ret) = @_;         # shallow copy of argument list 
    $sub->() for @ret;            # apply code to each copy
    wantarray ? @ret : pop @ret   # list in list context, last elem in scalar
}

apply creates a shallow copy of the argument list, and then calls its code block, which is expected to modify $_. The block's return value is not used. apply behaves like the comma , operator. In list context, it returns the list. In scalar context, it returns the last item in the list.

To use it:

my $new = apply {s/foo/bar/} $old;

my @new = apply {s/foo/bar/} qw( foot fool fooz );