In Groovy, how do I add up the values for a certain property in a map?

Question

I have the following map:

def map = [];
map.add([ item: "Shampoo", count: 5 ])
map.add([ item: "Soap", count: 3 ])

I would like to get the sum of all the count properties in the map. In C# using LINQ, it would be something like:

map.Sum(x => x.count)

How do I do the same in Groovy?

Answer 1

You want to use the collect operator. I checked the following code with groovysh:

list1 = []
total = 0
list1[0] = [item: "foo", count: 5]
list1[1] = [item: "bar", count: 3]
list1.collect{ total += it.count }
println "total = ${total}"

Answer 2

Assuming you have a list like so:

List list = [ [item: "foo", count: 5],
              [item: "bar", count: 3] ]

Then there are multiple ways of doing it. The most readable is probably

int a = list.count.sum()

Or you could use the Closure form of sum on the whole list

int b = list.sum { it.count }

Or you could even use a more complex route such as inject

int c = list.count.inject { tot, ele -> tot + ele } // Groovy 2.0
//  c = list.count.inject( 0 ) { tot, ele -> tot + ele } // Groovy < 2.0

All of these give the same result.

assert ( a == b ) && ( b == c ) && ( c == 8 )

I would use the first one.

Answer 3

First of all, you're confusing map and list syntax in your example. Anyhow, Groovy injects a .sum(closure) method to all collections.

Example:

[[a:1,b:2], [a:5,b:4]].sum { it.a }
===> 6