How to manipulate named tuples

Question

I like the idea of NamedTuple a lot, as a middle ground between Tuple and full, user-defined composite types.

I know how to build a named tuple and access one of its fields

julia> nt = (a=1, b=2.0)
(a = 1, b = 2.0)

julia> nt.a
1

however, I don't know much more and don't even know whether it is possible to do more than that. I'm thinking about a lot of ways we can manipulate plain tuples (usually involving splatting), and wonder if some of those apply to named tuples as well. For example, how to:

• dynamically build a NamedTuple from lists of fields and values
• grow a NamedTuple , i.e add new field-value pairs to it
• "update" (in an immutable sense) a field in an existing named tuple

Answer 1

The NamedTupleTools package contains a lot of tools aiming at making the use of NamedTuples more straightforward. But here are a few elementary operations that can be performed on them "manually":

Creation

       # regular syntax
julia> nt = (a=1, b=2.)
(a = 1, b = 2.0)

       # empty named tuple (useful as a seed that will later grow)
julia> NamedTuple()
NamedTuple()

       # only one entry => don't forget the comma
julia> (a=1,)
(a = 1,)

Growth and "modification"

It is possible to merge two named tuples to create a new one:

julia> merge(nt, (c=3, d=4.))
(a = 1, b = 2.0, c = 3, d = 4.0)

...or to re-use an existing NamedTuple by splatting it in the creation of a new one:

julia> (; nt..., c=3, d=4.)
(a = 1, b = 2.0, c = 3, d = 4.0)

When the same field name appears multiple times, the last occurrence is kept. This allows for a form of "copy with modification":

julia> nt
(a = 1, b = 2.0)

julia> merge(nt, (b=3,))
(a = 1, b = 3)

julia> (; nt..., b=3)
(a = 1, b = 3)

Dynamic manipulations

Using field=>value pairs in the various techniques presented above allows for more dynamic manipulations:

julia> field = :c;

julia> merge(nt, [field=>1])
(a = 1, b = 2.0, c = 1)

julia> (; nt..., field=>1)
(a = 1, b = 2.0, c = 1)

The same technique can be used to build NamedTuples from existing dynamic data structures

julia> dic = Dict(:a=>1, :b=>2);
julia> (; dic...)
(a = 1, b = 2)

julia> arr = [:a=>1, :b=>2];
julia> (; arr...)
(a = 1, b = 2)

Iteration

Iterating on a NamedTuple iterates on its values:

julia> for val in nt
           println(val)
       end
1
2.0

Like all key->value structures, the keys function can be used to iterate over the fields:

julia> for field in keys(nt)
           val = nt[field]
           println("$field => $val")
       end
a => 1
b => 2.0