How to create gradle task which always runs?

Question

I'm likely overlooking something pretty core/obvious, but how can I create a task that will always be executed for every task/target?

I can do something like:

task someTask << {
    println "I sometimes run"
}
println "I always run"

But it would be much more desirable to have the always running part in a task.

The closest I've come is:

task someTask << {
    println "I sometimes run"
}

println "I always run"

void helloThing() {
    println "I always run too. Hello?"
}

helloThing()

So, using a method is an 'ok' solution, but I was hoping there'd be a way to specifically designate/re-use a task.

Hopefully somebody has a way to do this. :)

Answer 1

This attaches a closure to every task in every project in the given build:

def someClosure = { task ->
  println "task executed: $task"
}

allprojects {
  afterEvaluate {
    for(def task in it.tasks)
      task << someClosure
  }
}

If you need the function/closure to be called only once per build, before all tasks of all projects, use this:

task('MyTask') << {
  println 'Pre-build hook!'
}

allprojects {
  afterEvaluate {
    for(def task in it.tasks)
      if(task != rootProject.tasks.MyTask)
        task.dependsOn rootProject.tasks.MyTask
  }
}

If you need the function/closure to be called only once per build, after all tasks of all projects, use this:

task('MyTask') << {
  println 'Post-build hook!'
}

allprojects {
  afterEvaluate {
    for(def task in it.tasks)
      if(task != rootProject.tasks.MyTask)
        task.finalizedBy rootProject.tasks.MyTask
  }
}