How to check if class type A extends class type B in groovy

Question

How to check if class type B extends class type A in groovy?

class A {
}

class B extends A {
}

Answer 1

Groovy's in operator will test for the is a relationship when the right-hand argument is a Class, so B in A is equivalent to Java's A.isAssignableFrom(B). This also works for objects. new C() in A is equivalent to new C() instanceof A.

Example

class A {}
class B extends A {}
class C extends B {}

assert C in A // C inherits from A

interface I {}
interface J extends I{}

assert J in I // J extends I

class D implements I {}

assert D in I // D implements I

final o = new C()
assert o in A // o is an instance of A

Answer 2

You can do it the same way as in Java:

A.isAssignableFrom(B)

See another Justin Piper's answer for Groovy in operator.

It seems awkward, but it means that B is a subclass of A. The height of inheritance hierarchy does not matter. It works also in case of interfaces.

Example

class A {}
class B extends A {}
class C extends B {}

assert A.isAssignableFrom(C) // C inherits from A

interface I {}
interface J extends I{}

assert I.isAssignableFrom(J) // J extends I

class D implements I {}

assert I.isAssignableFrom(D) // D implements I
    

See Class.isAssignableFrom.