How Do I Flatten The Directory Structure When UnZipping With Gradle?

Question

I want to extract some jars from a war as part of my gradle (2.0) build. So far I have this:

task unzip(type: Copy) {
    def zipFile = file('D:/external/dependent.war')
    def outputDir = file('lib')

    from zipTree(zipFile)
    into outputDir
    include 'WEB-INF/lib/*.jar'
}

This puts the WEB-INF/lib dir in the outputDir. I just want the jars flat.

To do it in Ant I would do this:

  <target name="unzip">
    <unzip src="D:/external/dependent.war" dest="lib">
        <patternset>
            <include name="WEB-INF/lib/*.jar"/>
        </patternset>
        <mapper type="flatten"/>
    </unzip>
  </target>

How do I do it in gradle?

Answer 1

I tried the answer by Al J, but it didn't work with the include.

This worked for me:

task unzip(type: Copy) {
    def zipFile = file('D:/external/dependent.war')
    def outputDir = file('lib')

    from zipTree(zipFile).matching{include 'WEB-INF/lib/*.jar'}.files
    into outputDir
}

Answer 2

I believe you can simply append .files to your zipTree.

task unzip(type: Copy) {
    def zipFile = file('D:/external/dependent.war')
    def outputDir = file('lib')

    from zipTree(zipFile).files
    into outputDir
    include 'WEB-INF/lib/*.jar'
}

Answer 3

It seems like there is a way with Gradle. It is more complicated though and not necessarily that obvious.

task unzip(type: Copy) {
    def zipFile = file('D:/external/dependent.war')
    def outputDir = file('lib')

    from zipTree(zipFile)
    into outputDir
    include '**/*.jar'
    includeEmptyDirs false
    eachFile { FileCopyDetails fcp ->
        // remap the file to the root
        String[] segments = [fcp.getName()]
        fcp.relativePath = new RelativePath(true, segments)
    }
}

includeEmptyDirs false makes sure that extra dirs aren't copied.

The eachFile block flattens the structure (you have to put the name into an array to make it work).

Answer 4

It seems like this is a bug/missing feature in Gradle http://issues.gradle.org/browse/GRADLE-3025

For now I am having to delegate to good old reliable Ant to do the work!

task unzip(){
  ant.unzip(src: 'D:/external/dependent.war', dest:'lib', overwrite:"true") {
    patternset( ) {
      include( name: 'WEB-INF/lib/*.jar' )
    }
    mapper(type:"flatten")
  }
}