How can I get my Perl regex to match only if $1 < $2?

Question

The part that I can't quite get to work is the conditional as it's always failing:

use Test::More tests => 2;

my $regex = qr/(\d+),(\d+)
               (?(?{\g1<\g2})(*FAIL))
              /x ;

  like( "(23,36)", $regex, 'should match'     );
unlike( "(36,23)", $regex, 'should not match' );

Output

not ok 1 - should match
#   Failed test 'should match'
#   at - line 7.
#                   '(23,36)'
#     doesn't match '(?^x:(\d+),(\d+)
#                    (?(?{\g1<\g2})(*FAIL))
#                   )'
ok 2 - should not match
# Looks like you failed 1 test of 2.

Answer 1

Your code needs the following fixes:

• Use the $1 and $2 variables in the experimental (?{ }) code block.
• Need to invert your test to match what you want to fail.
• You need to prevent backtracking where if the code block indicates a failure, you don't want it to match a substring that will pass, such as 6 is less then 23 in the second test. There are two methods to prevent this:
  • Add word boundaries so the regex can't match a partial number.
  • Use the (*SKIP) control verb to prevent backtracking explicitly.

The code:

use strict;
use warnings;

use Test::More tests => 2;

my $regex = qr/(\d+),(\d+)
               (?(?{$1 > $2})(*SKIP)(*FAIL))
              /x ;

  like( "(23,36)", $regex, 'should match'     );
unlike( "(36,23)", $regex, 'should not match' );

Outputs:

1..2
ok 1 - should match
ok 2 - should not match