Groovy equivalent for Java 8 Lambda Expression

Question

I have got this Java Interface with only one method.

// Java Interface
public interface AuditorAware {
    Auditor getCurrentAuditor();
}

I was using Java 8 Lambda expression to create insance of AuditorAware as following.

// Java 8 Lambda to create instance of AuditorAware
public AuditorAware currentAuditor() {
    return () -> AuditorContextHolder.getAuditor();
}

I am trying to write above Java implementation in Groovy.

I see there are many ways to implement interfaces in groovy as shown in this Groovy ways to implement interfaces documentation.

I have implemented above Java code to groovy equivalent by using implement interfaces with a map as shown in above mentioned documentation.

// Groovy Equivalent by "implement interfaces with a map" method
AuditorAware currentAuditor() {
    [getCurrentAuditor: AuditorContextHolder.auditor] as AuditorAware
}

But Implement interfaces with a closure method seems more concise as shown in documentation example. However, when I try to implement as follows, IntelliJ shows errors saying Ambiguous Code Block.

// Groovy Equivalent by "implement interfaces with a closure" method ???
AuditorAware currentAuditor() {
    {AuditorContextHolder.auditor} as AuditorAware
}

How can I change a Java 8 lambda implementation to groovy equivalent by using "implement interfaces with a closure" method?

Answer 1

As commented by Dylan Bijnagte, following code worked.

// Groovy Equivalent by "implement interfaces with a closure" method 
AuditorAware currentAuditor() {
    { -> AuditorContextHolder.auditor} as AuditorAware
}

Section Paramter Notes of Documentation on Groovy Closure explain this.

Answer 2

You can use the .& operator to get a method reference:

class Auditor { 
  String name 
}

interface AuditorAware { 
  Auditor getCurrentAuditor() 
}

class AuditorContextHolder {
  static getAuditor() { new Auditor(name: "joe") }
}

AuditorAware currentAuditor() {
  AuditorContextHolder.&getAuditor
}

assert currentAuditor().currentAuditor.name == "joe"

In Java 8 you can use the :: for method references:

  AuditorAware currentAuditor() {
    return AuditorContextHolder::getAuditor;
  }